Home | History | Annotate | Line # | Download | only in arm
modsi3.S revision 1.1.1.2.4.2 
      1 /*===-- modsi3.S - 32-bit signed integer modulus --------------------------===//
      2  *
      3  *                     The LLVM Compiler Infrastructure
      4  *
      5  * This file is dual licensed under the MIT and the University of Illinois Open
      6  * Source Licenses. See LICENSE.TXT for details.
      7  *
      8  *===----------------------------------------------------------------------===//
      9  *
     10  * This file implements the __modsi3 (32-bit signed integer modulus) function
     11  * for the ARM architecture as a wrapper around the unsigned routine.
     12  *
     13  *===----------------------------------------------------------------------===*/
     14 
     15 #include "../assembly.h"
     16 
     17 #define ESTABLISH_FRAME \
     18     push   {r4, r7, lr}    ;\
     19     add     r7,     sp, #4
     20 #define CLEAR_FRAME_AND_RETURN \
     21     pop    {r4, r7, pc}
     22 
     23 .syntax unified
     24 .align 3
     25 DEFINE_COMPILERRT_FUNCTION(__modsi3)
     26 #if __ARM_ARCH_EXT_IDIV__
     27 	tst     r1, r1
     28 	beq     LOCAL_LABEL(divzero)
     29 	sdiv	r2, r0, r1
     30 	mls 	r0, r2, r1, r0
     31 	bx      lr
     32 LOCAL_LABEL(divzero):
     33 	mov     r0, #0
     34 	bx      lr
     35 #else
     36     ESTABLISH_FRAME
     37     //  Set aside the sign of the dividend.
     38     mov     r4,     r0
     39     //  Take absolute value of a and b via abs(x) = (x^(x >> 31)) - (x >> 31).
     40     eor     r2,     r0, r0, asr #31
     41     eor     r3,     r1, r1, asr #31
     42     sub     r0,     r2, r0, asr #31
     43     sub     r1,     r3, r1, asr #31
     44     //  abs(a) % abs(b)
     45     bl     SYMBOL_NAME(__umodsi3)
     46     //  Apply sign of dividend to result and return.
     47     eor     r0,     r0, r4, asr #31
     48     sub     r0,     r0, r4, asr #31
     49     CLEAR_FRAME_AND_RETURN
     50 #endif
     51 END_COMPILERRT_FUNCTION(__modsi3)
     52