Home | History | Annotate | Line # | Download | only in arm
modsi3.S revision 1.1.1.3.4.2 
      1 /*===-- modsi3.S - 32-bit signed integer modulus --------------------------===//
      2  *
      3  *                     The LLVM Compiler Infrastructure
      4  *
      5  * This file is dual licensed under the MIT and the University of Illinois Open
      6  * Source Licenses. See LICENSE.TXT for details.
      7  *
      8  *===----------------------------------------------------------------------===//
      9  *
     10  * This file implements the __modsi3 (32-bit signed integer modulus) function
     11  * for the ARM architecture as a wrapper around the unsigned routine.
     12  *
     13  *===----------------------------------------------------------------------===*/
     14 
     15 #include "../assembly.h"
     16 
     17 #define ESTABLISH_FRAME \
     18     push   {r4, r7, lr}    ;\
     19     add     r7,     sp, #4
     20 #define CLEAR_FRAME_AND_RETURN \
     21     pop    {r4, r7, pc}
     22 
     23 	.syntax unified
     24 	.text
     25 #if __ARM_ARCH_ISA_THUMB == 2
     26 	.thumb
     27 #endif
     28 
     29 @ int __modsi3(int divident, int divisor)
     30 @   Calculate and return the remainder of the (signed) division.
     31 
     32 	.p2align 3
     33 DEFINE_COMPILERRT_FUNCTION(__modsi3)
     34 #if __ARM_ARCH_EXT_IDIV__
     35 	tst     r1, r1
     36 	beq     LOCAL_LABEL(divzero)
     37 	sdiv	r2, r0, r1
     38 	mls 	r0, r2, r1, r0
     39 	bx      lr
     40 LOCAL_LABEL(divzero):
     41 	mov     r0, #0
     42 	bx      lr
     43 #else
     44     ESTABLISH_FRAME
     45     //  Set aside the sign of the dividend.
     46     mov     r4,     r0
     47     //  Take absolute value of a and b via abs(x) = (x^(x >> 31)) - (x >> 31).
     48     eor     r2,     r0, r0, asr #31
     49     eor     r3,     r1, r1, asr #31
     50     sub     r0,     r2, r0, asr #31
     51     sub     r1,     r3, r1, asr #31
     52     //  abs(a) % abs(b)
     53     bl     SYMBOL_NAME(__umodsi3)
     54     //  Apply sign of dividend to result and return.
     55     eor     r0,     r0, r4, asr #31
     56     sub     r0,     r0, r4, asr #31
     57     CLEAR_FRAME_AND_RETURN
     58 #endif
     59 END_COMPILERRT_FUNCTION(__modsi3)
     60