Home | History | Annotate | Line # | Download | only in arm
modsi3.S revision 1.2 
      1 /*===-- modsi3.S - 32-bit signed integer modulus --------------------------===//
      2  *
      3  *                     The LLVM Compiler Infrastructure
      4  *
      5  * This file is dual licensed under the MIT and the University of Illinois Open
      6  * Source Licenses. See LICENSE.TXT for details.
      7  *
      8  *===----------------------------------------------------------------------===//
      9  *
     10  * This file implements the __modsi3 (32-bit signed integer modulus) function
     11  * for the ARM architecture as a wrapper around the unsigned routine.
     12  *
     13  *===----------------------------------------------------------------------===*/
     14 
     15 #include "../assembly.h"
     16 
     17 #define ESTABLISH_FRAME \
     18     push   {r4, r7, lr}    ;\
     19     add     r7,     sp, #4   ;\
     20     sub     sp,     #4
     21 #define CLEAR_FRAME_AND_RETURN \
     22     add     sp,     #4   ;\
     23     pop    {r4, r7, pc}
     24 
     25 	.syntax unified
     26 	.text
     27 #if __ARM_ARCH_ISA_THUMB == 2
     28 	.thumb
     29 #endif
     30 
     31 @ int __modsi3(int divident, int divisor)
     32 @   Calculate and return the remainder of the (signed) division.
     33 
     34 	.p2align 3
     35 #if __ARM_ARCH_ISA_THUMB == 2
     36 DEFINE_COMPILERRT_THUMB_FUNCTION(__modsi3)
     37 #else
     38 DEFINE_COMPILERRT_FUNCTION(__modsi3)
     39 #endif
     40 #if __ARM_ARCH_EXT_IDIV__
     41 	tst     r1, r1
     42 	beq     LOCAL_LABEL(divzero)
     43 	sdiv	r2, r0, r1
     44 	mls 	r0, r2, r1, r0
     45 	bx      lr
     46 LOCAL_LABEL(divzero):
     47 	mov     r0, #0
     48 	bx      lr
     49 #else
     50     ESTABLISH_FRAME
     51     //  Set aside the sign of the dividend.
     52     mov     r4,     r0
     53     //  Take absolute value of a and b via abs(x) = (x^(x >> 31)) - (x >> 31).
     54     eor     r2,     r0, r0, asr #31
     55     eor     r3,     r1, r1, asr #31
     56     sub     r0,     r2, r0, asr #31
     57     sub     r1,     r3, r1, asr #31
     58     //  abs(a) % abs(b)
     59     bl     SYMBOL_NAME(__umodsi3)
     60     //  Apply sign of dividend to result and return.
     61     eor     r0,     r0, r4, asr #31
     62     sub     r0,     r0, r4, asr #31
     63     CLEAR_FRAME_AND_RETURN
     64 #endif
     65 END_COMPILERRT_FUNCTION(__modsi3)
     66