Home | History | Annotate | Line # | Download | only in gnuefi
elf_x86_64_efi.lds revision 1.1.1.1.10.2 
      1 /*	$NetBSD: elf_x86_64_efi.lds,v 1.1.1.1.10.2 2014/08/20 00:04:23 tls Exp $	*/
      2 
      3 /* Same as elf_x86_64_fbsd_efi.lds, except for OUTPUT_FORMAT below - KEEP IN SYNC */
      4 OUTPUT_FORMAT("elf64-x86-64", "elf64-x86-64", "elf64-x86-64")
      5 OUTPUT_ARCH(i386:x86-64)
      6 ENTRY(_start)
      7 SECTIONS
      8 {
      9   . = 0;
     10   ImageBase = .;
     11   .hash : { *(.hash) }	/* this MUST come first! */
     12   . = ALIGN(4096);
     13   .eh_frame :
     14   {
     15     *(.eh_frame)
     16   }
     17   . = ALIGN(4096);
     18   .text :
     19   {
     20    *(.text)
     21    *(.text.*)
     22    *(.gnu.linkonce.t.*)
     23   }
     24   . = ALIGN(4096);
     25   .reloc :
     26   {
     27    *(.reloc)
     28   }
     29   . = ALIGN(4096);
     30   .data :
     31   {
     32    *(.rodata*)
     33    *(.got.plt)
     34    *(.got)
     35    *(.data*)
     36    *(.sdata)
     37    /* the EFI loader doesn't seem to like a .bss section, so we stick
     38       it all into .data: */
     39    *(.sbss)
     40    *(.scommon)
     41    *(.dynbss)
     42    *(.bss)
     43    *(COMMON)
     44    *(.rel.local)
     45   }
     46   . = ALIGN(4096);
     47   .dynamic  : { *(.dynamic) }
     48   . = ALIGN(4096);
     49   .rela :
     50   {
     51     *(.rela.data*)
     52     *(.rela.got)
     53     *(.rela.stab)
     54   }
     55   . = ALIGN(4096);
     56   .dynsym   : { *(.dynsym) }
     57   . = ALIGN(4096);
     58   .dynstr   : { *(.dynstr) }
     59   . = ALIGN(4096);
     60   .ignored.reloc :
     61   {
     62     *(.rela.reloc)
     63     *(.eh_frame)
     64     *(.note.GNU-stack)
     65   }
     66   .comment 0 : { *(.comment) }
     67 }
     68