Home | History | Annotate | Line # | Download | only in x86_64
h_execregs.S revision 1.1 
      1 /*	$NetBSD: h_execregs.S,v 1.1 2025/02/27 00:55:32 riastradh Exp $	*/
      2 
      3 /*-
      4  * Copyright (c) 2025 The NetBSD Foundation, Inc.
      5  * All rights reserved.
      6  *
      7  * Redistribution and use in source and binary forms, with or without
      8  * modification, are permitted provided that the following conditions
      9  * are met:
     10  * 1. Redistributions of source code must retain the above copyright
     11  *    notice, this list of conditions and the following disclaimer.
     12  * 2. Redistributions in binary form must reproduce the above copyright
     13  *    notice, this list of conditions and the following disclaimer in the
     14  *    documentation and/or other materials provided with the distribution.
     15  *
     16  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
     17  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     18  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     19  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
     20  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     21  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     22  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     23  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     24  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     25  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     26  * POSSIBILITY OF SUCH DAMAGE.
     27  */
     28 
     29 #define	_LOCORE
     30 
     31 #include <sys/syscall.h>
     32 
     33 #include <machine/asm.h>
     34 
     35 #include "execregs.h"
     36 
     37 ENTRY(execregs_start)
     38 	andq	$-0x10,%rsp		/* align stack to 16-byte boundary */
     39 
     40 	/* store registers to a buffer on stack */
     41 	subq	$(NEXECREGS*8),%rsp	/* space for NEXECREGS registers */
     42 	movq	%rdi,0*8(%rsp)		/* order matches execregs.h */
     43 	movq	%rsi,1*8(%rsp)
     44 	movq	%rdx,2*8(%rsp)
     45 	movq	%r10,3*8(%rsp)
     46 	movq	%r8,4*8(%rsp)
     47 	movq	%r9,5*8(%rsp)
     48 	movq	%rcx,6*8(%rsp)
     49 	movq	%r11,7*8(%rsp)
     50 	movq	%r12,8*8(%rsp)
     51 	movq	%r13,9*8(%rsp)
     52 	movq	%r14,10*8(%rsp)
     53 	movq	%r15,11*8(%rsp)
     54 	movq	%rbp,12*8(%rsp)
     55 	movq	%rax,13*8(%rsp)
     56 
     57 	/* call write(STDOUT_FILENO, regs, sizeof(regs)) */
     58 	movl	$0x1,%edi		/* arg0 := STDOUT_FILENO */
     59 	movq	%rsp,%rsi		/* arg1 := regs */
     60 	movl	$(NEXECREGS*8),%edx	/* arg2 := sizeof(regs) */
     61 	movl	$SYS_write,%eax		/* syscall number */
     62 	syscall
     63 
     64 	jb	2f			/* bail if write failed */
     65 	cmpq	$(NEXECREGS*8),%rax	/* bail if wrote wrong # of bytes */
     66 	jne	2f
     67 
     68 	/* call exit(0) */
     69 	xorl	%edi,%edi		/* arg0 := 0 */
     70 1:	movl	$SYS_exit,%eax		/* syscall number */
     71 	syscall
     72 	hlt				/* paranoia */
     73 
     74 2:	/* call exit(127) */
     75 	movl	$127,%edi		/* arg0 := 127 */
     76 	jmp	1b
     77 END(execregs_start)
     78 
     79 /* main stub to simplify linking */
     80 ENTRY(main)
     81 	hlt
     82 END(main)
     83