Home | History | Annotate | Line # | Download | only in compat
configure.ac revision 1.26 
      1 #	$NetBSD: configure.ac,v 1.26 2002/10/05 04:13:30 lukem Exp $
      2 #
      3 # Autoconf definition file for libnbcompat.
      4 #
      5 
      6 AC_INIT([libnbcompat], [noversion], [lib-bug-people (a] netbsd.org])
      7 AC_CONFIG_HEADERS(config.h)
      8 AC_CONFIG_FILES(defs.mk)
      9 
     10 AC_PATH_PROG(BSHELL, sh, )
     11 if test x"$BSHELL" = x; then
     12 	AC_MSG_ERROR([sh must be somewhere on \$PATH])
     13 fi
     14 AC_DEFINE_UNQUOTED(PATH_BSHELL, "$BSHELL")
     15 
     16 AC_C_BIGENDIAN
     17 AC_HEADER_STDC
     18 
     19 # Confirm existence of zlib.  (This is available as a default install
     20 # option on many OS's; this could be added as a reachover build in the
     21 # future.)
     22 AC_CHECK_HEADER(zlib.h,,
     23 	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
     24 AC_CHECK_LIB(z, gzdopen,,
     25 	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
     26 
     27 # Make sure certain required headers are available.
     28 # These are not necessarily required by the code, but they are not
     29 # currently conditionalized.
     30 AC_CHECK_HEADERS(sys/ioctl.h sys/mman.h sys/mtio.h sys/param.h \
     31 	sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h \
     32 	assert.h ctype.h errno.h fcntl.h grp.h limits.h locale.h \
     33 	netdb.h poll.h pwd.h signal.h stdarg.h stdio.h stdlib.h string.h \
     34 	termios.h unistd.h,,
     35 	AC_MSG_ERROR([standard system header file not found]))
     36 
     37 # Find headers that may not be available.
     38 AC_HEADER_DIRENT
     39 AC_CHECK_HEADERS(sys/sysmacros.h sys/syslimits.h \
     40 	features.h malloc.h stddef.h)
     41 AC_CHECK_HEADERS(machine/bswap.h sys/cdefs.h sys/endian.h sys/featuretest.h \
     42 	err.h inttypes.h libgen.h paths.h stdint.h util.h,,
     43 	[test -f include/$ac_header || touch include/$ac_header])
     44 AC_CHECK_HEADERS(rpc/types.h getopt.h netconfig.h,,
     45 	[echo '#include "config.h"' >include/$ac_header.new
     46 	echo '#include "'$srcdir/../../include/$ac_header'"' >>include/$ac_header.new
     47 	if cmp include/$ac_header.new include/$ac_header >/dev/null 2>&1; then
     48 		rm -f include/$ac_header.new
     49 	else
     50 		mv -f include/$ac_header.new include/$ac_header
     51 	fi])
     52 
     53 # Typedefs.
     54 AC_TYPE_SIZE_T
     55 AC_CHECK_TYPES([id_t, long long, u_quad_t])
     56 
     57 dnl XXX - This is UGLY.  Need a better way to homogenize the bitsized types,
     58 dnl including use of compiler primitive types via AC_CHECK_SIZEOF.
     59 dnl
     60 define([NB_CHECK_INTTYPE], [
     61 	AC_CHECK_TYPE(uint][$1][_t,, [
     62 		AC_CHECK_TYPE(u_int][$1][_t,
     63 			AC_DEFINE(uint][$1][_t, u_int][$1][_t),
     64 			AC_MSG_ERROR([cannot find a suitable type for uint][$1][_t]))
     65 	])
     66 	AC_CHECK_TYPE(u_int][$1][_t,, [
     67 		AC_CHECK_TYPE(uint][$1][_t,
     68 			AC_DEFINE(u_int][$1][_t, uint][$1][_t),
     69 			AC_MSG_ERROR([cannot find a suitable type for u_int][$1][_t]))
     70 	])
     71 ])
     72 
     73 NB_CHECK_INTTYPE(8)
     74 NB_CHECK_INTTYPE(16)
     75 NB_CHECK_INTTYPE(32)
     76 NB_CHECK_INTTYPE(64)
     77 
     78 # Struct members.
     79 AC_CHECK_MEMBERS([DIR.dd_fd, struct dirent.d_namlen],,,
     80 	[#include <dirent.h>])
     81 AC_CHECK_MEMBERS([struct stat.st_flags, struct stat.st_gen,
     82 	struct stat.st_mtimensec],,, [#include <sys/stat.h>])
     83 AC_CHECK_MEMBERS(struct statfs.f_iosize,,, [#include <sys/mount.h>])
     84 
     85 # Global variable decls.
     86 AC_CHECK_DECLS([optind, optreset],,, [
     87 #include <stdio.h>
     88 #include <stdlib.h>
     89 #include <unistd.h>
     90 ])
     91 AC_CHECK_DECLS(sys_signame,,, [#include <signal.h>])
     92 
     93 # Library functions (where a .h check isn't enough).
     94 AC_FUNC_ALLOCA
     95 AC_SEARCH_LIBS(fparseln, util)
     96 AC_CHECK_FUNCS(asprintf asnprintf basename dirfd dirname \
     97 	fgetln flock fparseln futimes getopt getopt_long \
     98 	isblank issetugid lchflags lchmod lchown lutimes mkstemp mkdtemp \
     99 	poll pread pwcache_userdb pwrite random setenv setgroupent \
    100 	setprogname setpassent snprintf strlcat strlcpy strsep \
    101 	user_from_uid vasprintf vasnprintf vsnprintf)
    102 
    103 AC_CHECK_DECLS([setgroupent, setpassent],,, [
    104 #include <grp.h>
    105 #include <pwd.h>
    106 ])
    107 
    108 # regcomp() and regexec() are also names of functions in the old V8
    109 # regexp package.  To avoid them, we need to find out who has regfree().
    110 
    111 dnl # Cygwin: We *MUST* look at -lregex *before* the "no libs" condition.
    112 dnl # Thus AC_CHECK_LIB(regex...) comes first, and AC_SEARCHLIBS next.
    113 AC_CHECK_LIB(regex, regfree)
    114 AC_SEARCH_LIBS(regfree, rx posix)
    115 
    116 AC_OUTPUT
    117