Home | History | Annotate | Line # | Download | only in compat
configure.ac revision 1.8 
      1 #	$NetBSD: configure.ac,v 1.8 2002/02/26 22:29:39 tv Exp $
      2 #
      3 # Autoconf definition file for libnbcompat.
      4 #
      5 
      6 AC_INIT([libnbcompat], [noversion], [lib-bug-people (a] netbsd.org])
      7 AC_CONFIG_HEADERS(config.h)
      8 AC_CONFIG_FILES(defs.mk)
      9 
     10 AC_C_BIGENDIAN
     11 AC_HEADER_STDC
     12 
     13 # Confirm existence of zlib.  (This is available as a default install
     14 # option on many OS's; this could be added as a reachover build in the
     15 # future.)
     16 AC_CHECK_HEADER(zlib.h,,
     17 	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
     18 AC_CHECK_LIB(z, gzdopen,,
     19 	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
     20 
     21 # Make sure certain required headers are available.
     22 # These are not necessarily required by the code, but they are not
     23 # currently conditionalized.
     24 AC_CHECK_HEADERS(sys/ioctl.h sys/mman.h sys/mtio.h sys/param.h \
     25 	sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h \
     26 	assert.h ctype.h errno.h fcntl.h grp.h limits.h locale.h \
     27 	netdb.h pwd.h signal.h stdarg.h stdio.h stdlib.h string.h \
     28 	unistd.h,,
     29 	AC_MSG_ERROR([standard system header file not found]))
     30 
     31 # Find headers that may not be available.
     32 AC_HEADER_DIRENT
     33 AC_CHECK_HEADERS(sys/sysmacros.h sys/syslimits.h features.h inttypes.h malloc.h stddef.h stdint.h)
     34 AC_CHECK_HEADERS(machine/bswap.h sys/cdefs.h sys/featuretest.h \
     35 	err.h libgen.h paths.h util.h,, [touch include/$ac_header])
     36 AC_CHECK_HEADERS(rpc/types.h fts.h getopt.h netconfig.h vis.h,,
     37 	[echo '#include "'$srcdir/../../include/$ac_header'"' >include/$ac_header])
     38 
     39 # Typedefs.
     40 AC_TYPE_SIZE_T
     41 AC_CHECK_TYPES([id_t, long long, u_quad_t])
     42 
     43 define([NB_CHECK_INTTYPE], [
     44 	AC_CHECK_TYPE(u_int][$1][_t,, [
     45 		AC_CHECK_TYPE(uint][$1][_t,
     46 			AC_DEFINE(u_int][$1][_t, uint][$1][_t),
     47 			AC_MSG_ERROR([cannot find a suitable type for u_int][$1][_t]))
     48 	])
     49 ])
     50 
     51 NB_CHECK_INTTYPE(8)
     52 NB_CHECK_INTTYPE(16)
     53 NB_CHECK_INTTYPE(32)
     54 NB_CHECK_INTTYPE(64)
     55 
     56 # Struct members.
     57 AC_CHECK_MEMBERS([DIR.dd_fd, struct dirent.d_namlen],,,
     58 	[#include <dirent.h>])
     59 AC_CHECK_MEMBERS([struct stat.st_flags, struct stat.st_gen,
     60 	struct stat.st_mtimensec],,, [#include <sys/stat.h>])
     61 AC_CHECK_MEMBERS(struct statfs.f_iosize,,, [#include <sys/mount.h>])
     62 
     63 # Global variable decls.
     64 AC_CHECK_DECLS([optind, optreset],,, [
     65 #include <stdio.h>
     66 #include <stdlib.h>
     67 #include <unistd.h>
     68 ])
     69 AC_CHECK_DECLS(sys_signame,,, [#include <signal.h>])
     70 
     71 # Library functions (where a .h check isn't enough).
     72 AC_SEARCH_LIBS(fparseln, util)
     73 AC_CHECK_FUNCS(asprintf asnprintf basename dirfd dirname \
     74 	fgetln flock fparseln futimes getopt getopt_long \
     75 	isblank lchmod lchown lutimes pread pwcache_userdb \
     76 	pwrite setenv setgroupent setprogname setpassent \
     77 	snprintf strlcat strlcpy strsep vasprintf vasnprintf vsnprintf)
     78 
     79 AC_CHECK_DECLS([setgroupent, setpassent],,, [
     80 #include <grp.h>
     81 #include <pwd.h>
     82 ])
     83 
     84 # regcomp() and regexec() are also names of functions in the old V8
     85 # regexp package.  To avoid them, we need to find out who has regfree().
     86 
     87 dnl # Cygwin: We *MUST* look at -lregex *before* the "no libs" condition.
     88 dnl # Thus AC_CHECK_LIB(regex...) comes first, and AC_SEARCHLIBS next.
     89 AC_CHECK_LIB(regex, regfree)
     90 AC_SEARCH_LIBS(regfree, rx posix)
     91 
     92 AC_OUTPUT
     93