Home | History | Annotate | Line # | Download | only in compat
configure.ac revision 1.96 
      1 #	$NetBSD: configure.ac,v 1.96 2019/06/19 23:33:07 kamil Exp $
      2 #
      3 # Autoconf definition file for libnbcompat.
      4 #
      5 # When you edit configure.ac:
      6 # 0. Create the tools versions of autoconf and autoheader:
      7 #        cd ${SRCDIR} && build.sh -V MKMAINTAINERTOOLS=yes tools
      8 #    (This might not work if you try it after editing configure.ac.)
      9 # 1. edit configure.ac
     10 # 2. Regenerate "configure" and "nbtool_config.h.in" from "configure.ac":
     11 #        cd ${SRCDIR}/tools/compat && ${TOOLDIR}/bin/nbmake-${MACHINE} regen
     12 #    (Please don't use a non-tools version of autoconf or autoheader.)
     13 # 3. Test that the tools still build:
     14 #        mv ${TOOLDIR} ${TOOLDIR}.bak
     15 #        cd ${SRCDIR} && build.sh -V MKMAINTAINERTOOLS=yes tools
     16 # 4. cvs commit files that you edited.
     17 # 5. Regen again, to pick up changed RCS IDs from the above commit:
     18 #        cd ${SRCDIR}/tools/compat && ${TOOLDIR}/bin/nbmake-${MACHINE} regen
     19 # 6. cvs commit files that were generated.
     20 #
     21 
     22 AC_INIT([libnbcompat], [noversion], [lib-bug-people (a] NetBSD.org])
     23 AC_CONFIG_HEADERS(nbtool_config.h)
     24 AC_CONFIG_FILES(defs.mk)
     25 
     26 # Autoheader header and footer
     27 AH_TOP([/*      $][NetBSD$    */
     28  
     29 #ifndef __NETBSD_NBTOOL_CONFIG_H__
     30 #define __NETBSD_NBTOOL_CONFIG_H__])
     31 
     32 AH_BOTTOM([#include "compat_defs.h"
     33 #endif /* !__NETBSD_NBTOOL_CONFIG_H__ */])
     34 
     35 AC_DEFUN([AC_NETBSD],
     36 [AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
     37       AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
     38       AC_MSG_CHECKING([for NetBSD])
     39       AC_EGREP_CPP(yes,
     40       [#ifdef __NetBSD__
     41 	yes
     42 	#endif
     43 	],
     44 	[AC_MSG_RESULT([yes])
     45 	 AC_DEFINE([_POSIX_SOURCE], 1, [Define for NetBSD headers.])
     46 	 AC_DEFINE([_POSIX_C_SOURCE], 200112L, [Define for NetBSD headers.])
     47 	 AC_DEFINE([_XOPEN_SOURCE], 600, [Define for NetBSD headers.])],
     48 	[AC_MSG_RESULT([no])])
     49 ])# AC_NETBSD
     50 
     51 AC_NETBSD
     52 AC_PATH_PROG(BSHELL, sh, )
     53 if test x"$BSHELL" = x; then
     54 	AC_MSG_ERROR([sh must be somewhere on \$PATH])
     55 fi
     56 AC_DEFINE_UNQUOTED([PATH_BSHELL], "$BSHELL", [Path to sh(1).])
     57 
     58 AC_C_BIGENDIAN
     59 AC_HEADER_STDC
     60 
     61 # Confirm existence of zlib.  (This is available as a default install
     62 # option on many OS's; this could be added as a reachover build in the
     63 # future.)
     64 AC_CHECK_HEADER(zlib.h,,
     65 	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
     66 AC_CHECK_LIB(z, gzdopen,,
     67 	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
     68 
     69 # Make sure certain required headers are available.
     70 # These are not necessarily required by the code, but they are not
     71 # currently conditionalized.
     72 AC_CHECK_HEADERS(sys/ioctl.h sys/mman.h sys/param.h \
     73 	sys/socket.h sys/stat.h sys/time.h sys/types.h sys/utsname.h \
     74 	sys/wait.h assert.h ctype.h errno.h fcntl.h grp.h limits.h locale.h \
     75 	netdb.h pwd.h signal.h stdarg.h stdio.h stdlib.h string.h \
     76 	termios.h unistd.h,,
     77 	AC_MSG_ERROR([standard system header file not found]))
     78 
     79 # Find headers that may not be available.
     80 AC_HEADER_DIRENT
     81 AC_CHECK_HEADERS(sys/mtio.h sys/sysmacros.h sys/syslimits.h stdio_ext.h \
     82 	getopt.h features.h malloc.h sys/poll.h pthread.h stddef.h rpc/types.h \
     83 	sys/uio.h)
     84 AC_CHECK_HEADERS(sys/bswap.h machine/bswap.h sys/cdefs.h machine/endian.h \
     85 	sys/endian.h sys/featuretest.h err.h inttypes.h libgen.h paths.h \
     86 	libgen.h stdint.h util.h resolv.h arpa/nameser.h,,
     87 	[test -f include/$ac_header || touch include/$ac_header])
     88 AC_CHECK_HEADERS(rpc/types.h netconfig.h,,
     89 	[echo '#include "nbtool_config.h"' >include/$ac_header.new
     90 	echo '#include "'$srcdir/../../include/$ac_header'"' \
     91 		>>include/$ac_header.new
     92 	if cmp include/$ac_header.new include/$ac_header >/dev/null 2>&1; then
     93 		rm -f include/$ac_header.new
     94 	else
     95 		mv -f include/$ac_header.new include/$ac_header
     96 	fi])
     97 
     98 # Typedefs.
     99 AC_TYPE_SIZE_T
    100 AC_CHECK_TYPES([id_t, long long, u_long, u_char, u_short, u_int, u_quad_t])
    101 AC_CHECK_TYPES([uchar_t, ushort_t, uint_t, ulong_t])
    102 AC_CHECK_TYPE(socklen_t, [AC_DEFINE([HAVE_SOCKLEN_T], 1,
    103 			  [Define if you have the socklen_t type.])],,
    104 [#include <sys/types.h>
    105 #ifdef HAVE_RPC_TYPES_H
    106 #include <rpc/types.h>
    107 #endif
    108 #include <sys/socket.h>])
    109 
    110 AC_MSG_CHECKING([for enum uio_rw])
    111 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
    112 #include <sys/types.h>
    113 #ifdef HAVE_SYS_UIO_H
    114 #include <sys/uio.h>
    115 #endif]],
    116 [[enum uio_rw rw;]])],[AC_DEFINE([HAVE_ENUM_UIO_RW], 1,
    117 			    [Define if you have the enum uio_rw type.])],)
    118 
    119 AC_MSG_CHECKING([for enum uio_seg])
    120 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
    121 #include <sys/types.h>
    122 #ifdef HAVE_SYS_UIO_H
    123 #include <sys/uio.h>
    124 #endif]],
    125 [[enum uio_seg seg;]])],[AC_DEFINE([HAVE_ENUM_UIO_SEG], 1,
    126 			    [Define if you have the enum uio_seg type.])],)
    127 
    128 dnl XXX - This is UGLY.  Need a better way to homogenize the bitsized types,
    129 dnl including use of compiler primitive types via AC_CHECK_SIZEOF.
    130 dnl
    131 define([NB_CHECK_INTTYPE], [
    132 	AC_CHECK_TYPE(uint][$1][_t,, [
    133 		AC_CHECK_TYPE(u_int][$1][_t,
    134 			AC_DEFINE(uint][$1][_t, u_int][$1][_t, \
    135 			          [Define if you have u_int][$1][_t, but not uint][$1][_t.]),
    136 			AC_MSG_ERROR([cannot find a suitable type for uint][$1][_t]))
    137 	])
    138 	AC_CHECK_TYPE(u_int][$1][_t,, [
    139 		AC_CHECK_TYPE(uint][$1][_t,
    140 			AC_DEFINE(u_int][$1][_t, uint][$1][_t, \
    141 				  [Define if you have uint][$1][_t, but not u_int][$1][_t.]),
    142 			AC_MSG_ERROR([cannot find a suitable type for u_int][$1][_t]))
    143 	])
    144 ])
    145 
    146 NB_CHECK_INTTYPE(8)
    147 NB_CHECK_INTTYPE(16)
    148 NB_CHECK_INTTYPE(32)
    149 NB_CHECK_INTTYPE(64)
    150 
    151 # Struct members.
    152 AC_CHECK_MEMBERS([DIR.dd_fd, DIR.__dd_fd, struct dirent.d_namlen],,,
    153 [#include <sys/types.h>
    154 #include <dirent.h>])
    155 AC_CHECK_MEMBERS([struct stat.st_flags, struct stat.st_gen,
    156 	struct stat.st_birthtime, struct stat.st_birthtimensec,
    157 	struct stat.st_atim, struct stat.st_mtimensec],,, 
    158 	[#include <sys/stat.h>])
    159 AC_CHECK_MEMBERS(struct statvfs.f_iosize,,, [#include <sys/statvfs.h>])
    160 AC_CHECK_MEMBERS(struct tm.tm_gmtoff,,, [#include <time.h>])
    161 
    162 # Global variable decls.
    163 AC_CHECK_DECLS([asprintf, asnprintf, vasprintf, vasnprintf, vsnprintf, fgetln, fparseln,
    164 	fpurge, getdelim, getline, snprintf],,, [
    165 #include <stdio.h>
    166 ])
    167 
    168 AC_CHECK_DECLS([atoll, heapsort, mkdtemp, mkstemp, reallocarr, getsubopt,
    169 	setenv, strtoi, strtoll, strtou, setprogname, getprogname],,, [
    170 #include <stdlib.h>
    171 ])
    172 
    173 AC_CHECK_DECLS([basename, dirname],,, [
    174 #include <libgen.h>
    175 ])
    176 
    177 AC_CHECK_DECLS([raise_default_signal],,, [
    178 #include <util.h>
    179 ])
    180 
    181 AC_CHECK_DECLS([issetugid, pread, pwrite],,, [
    182 #include <unistd.h>
    183 ])
    184 
    185 AC_CHECK_DECLS([strmode],,, [
    186 #include <unistd.h>
    187 #include <string.h>
    188 ])
    189 
    190 AC_CHECK_DECLS([isblank],,, [
    191 #include <ctype.h>
    192 ])
    193 
    194 
    195 AC_CHECK_DECLS([optind, optreset],,, [
    196 #include <stdio.h>
    197 #include <stdlib.h>
    198 #include <unistd.h>
    199 #ifdef HAVE_GETOPT_H
    200 #include <getopt.h>
    201 #endif
    202 ])
    203 AC_CHECK_DECLS(sys_signame,,, [#include <signal.h>])
    204 
    205 # Library functions (where a .h check isn't enough).
    206 AC_FUNC_ALLOCA
    207 AC_CHECK_FUNCS(atoll asprintf asnprintf basename devname dirfd dirname \
    208 	dprintf esetfunc fgetln flock fpurge __fpurge futimes getline \
    209 	getopt getopt_long group_from_gid gid_from_group \
    210 	heapsort isblank issetugid lchflags lchmod lchown lutimes mkstemp \
    211 	mkdtemp poll pread putc_unlocked pwcache_userdb pwcache_groupdb \
    212 	pwrite raise_default_signal random reallocarr setenv \
    213 	setgroupent setprogname setpassent \
    214 	snprintb_m snprintf strlcat strlcpy strmode \
    215 	strcasecmp strncasecmp strndup strnlen strsep strsuftoll strtoi \
    216 	strtoll strtou \
    217 	user_from_uid uid_from_user vasprintf vasnprintf vsnprintf)
    218 
    219 AC_CHECK_DECLS([user_from_uid, uid_from_user, pwcache_userdb],,,[
    220 #include <pwd.h>
    221 ])
    222 AC_CHECK_DECLS([group_from_gid, gid_from_group, pwcache_groupdb],,,[
    223 #include <grp.h>
    224 ])
    225 AC_CHECK_DECLS([strcasecmp, strncasecmp, strlcpy, strlcat, strndup,
    226 		strnlen, strsep],,,[
    227 #include <string.h>
    228 ])
    229 AC_CHECK_DECLS([strsuftoll, mi_vector_hash],,,[#include <stdlib.h>])
    230 AC_CHECK_DECLS([lchflags, lchmod, lchown],,,[
    231 #include <sys/stat.h>
    232 #include <unistd.h>
    233 ])
    234 
    235 AC_CHECK_DECLS([err, errc, errx, verrc, verrx, warn, warnc, warnx, vwarnc,
    236 		vwarnx],,,[
    237 #ifdef HAVE_ERR_H
    238 #include <err.h>
    239 #endif
    240 ])
    241 
    242 AC_CHECK_DECLS([htobe16, htobe32, htobe64, htole16, htole32, htole64,
    243 		be16toh, be32toh, be64toh, le16toh, le32toh, le64toh],,,
    244 		[#include <sys/types.h>])
    245 
    246 AC_CHECK_DECLS([bswap16, bswap32, bswap64],,, [#include <machine/bswap.h>])
    247 
    248 AC_CHECK_DECLS([be16enc, le16enc, be16dec, le16dec, be32enc, le32enc,
    249 		be32dec, le32dec, be64enc, le64enc, be64dec, le64dec],,,
    250 		[#include <sys/endian.h>])
    251 
    252 AC_CHECK_DECLS([fstatvfs],,, [#include <sys/statvfs.h>])
    253 
    254 AC_CHECK_DECLS([setgroupent, setpassent],,, [
    255 #include <sys/types.h>
    256 #include <grp.h>
    257 #include <pwd.h>
    258 ])
    259 
    260 # regcomp() and regexec() are also names of functions in the old V8
    261 # regexp package.  To avoid them, we need to find out who has regfree().
    262 
    263 dnl # Cygwin: We *MUST* look at -lregex *before* the "no libs" condition.
    264 dnl # Thus AC_CHECK_LIB(regex...) comes first, and AC_SEARCHLIBS next.
    265 AC_CHECK_LIB(regex, regfree)
    266 AC_SEARCH_LIBS(regfree, rx posix)
    267 
    268 AC_CHECK_LIB(rt, clock_gettime)
    269 
    270 AC_CHECK_FUNCS(fparseln, [
    271     AC_MSG_CHECKING(if fparseln seems to work)
    272     AC_RUN_IFELSE(
    273         [AC_LANG_SOURCE([[
    274 #define _NETBSD_SOURCE
    275 #include <stdio.h>
    276 #include <stdlib.h>
    277 #define CONFTEST	"conftest.fparseln"
    278 #define COMMENT		'#'
    279 int
    280 main(void)
    281 {
    282 	static const char delim[3] = { '\0', '\0', COMMENT };
    283 	FILE *fp;
    284 	char *ptr;
    285 	fp = fopen(CONFTEST, "w+");
    286 	if (fp != NULL) {
    287 		unlink(CONFTEST);
    288 		ungetc(COMMENT, fp);
    289 		ptr = fparseln(fp, NULL, NULL, delim,
    290 		    FPARSELN_UNESCALL);
    291 		fclose(fp);
    292 		if (ptr == NULL)
    293 			exit(0);
    294 	}
    295 	exit(1);
    296 }
    297         ]])],
    298         [AC_MSG_RESULT(yes)],
    299         [AC_MSG_RESULT(no)
    300          AC_DEFINE(BROKEN_FPARSELN, 1,
    301             [Define to 1 if your `fparseln' function is broken.])],
    302         [AC_MSG_WARN([cross compiling: not checking farseln])]
    303     )
    304 ])
    305 
    306 # Variables substituted via @VARNAME@ in defs.mk.in
    307 AC_SUBST(HAVE_PTHREAD_H, $ac_cv_header_pthread_h)
    308 
    309 AC_OUTPUT
    310