configure.ac revision c7b4381a 
1#  Copyright © 2003 Keith Packard
2#
3#  Permission to use, copy, modify, distribute, and sell this software and its
4#  documentation for any purpose is hereby granted without fee, provided that
5#  the above copyright notice appear in all copies and that both that
6#  copyright notice and this permission notice appear in supporting
7#  documentation, and that the name of Keith Packard not be used in
8#  advertising or publicity pertaining to distribution of the software without
9#  specific, written prior permission.  Keith Packard makes no
10#  representations about the suitability of this software for any purpose.  It
11#  is provided "as is" without express or implied warranty.
12#
13#  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
14#  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
15#  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
16#  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
17#  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
18#  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
19#  PERFORMANCE OF THIS SOFTWARE.
20#
21
22# Initialize Autoconf
23AC_PREREQ([2.60])
24AC_INIT([libXfont2], [2.0.4],
25	[https://gitlab.freedesktop.org/xorg/lib/libXfont/issues], [libXfont2])
26AC_CONFIG_SRCDIR([Makefile.am])
27AC_CONFIG_HEADERS([config.h])
28
29# Initialize Automake
30AM_INIT_AUTOMAKE([foreign dist-bzip2 subdir-objects])
31
32# Set common system defines for POSIX extensions, such as _GNU_SOURCE
33# Must be called before any macros that run the compiler (like
34# AC_PROG_LIBTOOL) to avoid autoconf errors.
35AC_USE_SYSTEM_EXTENSIONS
36
37# Initialize libtool
38AC_PROG_LIBTOOL
39
40# Require xorg-macros minimum of 1.10 for DocBook XML documentation
41m4_ifndef([XORG_MACROS_VERSION],
42          [m4_fatal([must install xorg-macros 1.10 or later before running autoconf/autogen])])
43XORG_MACROS_VERSION(1.10)
44XORG_DEFAULT_OPTIONS
45XORG_ENABLE_DEVEL_DOCS
46XORG_WITH_XMLTO(0.0.22)
47XORG_WITH_FOP
48XORG_CHECK_SGML_DOCTOOLS(1.7)
49
50# Checks for header files.
51AC_CHECK_HEADERS([endian.h poll.h sys/poll.h])
52
53# Checks for library functions.
54AC_CHECK_FUNCS([poll readlink])
55AC_SEARCH_LIBS([strlcat], [bsd])
56AC_CONFIG_LIBOBJ_DIR([src/util])
57AC_REPLACE_FUNCS([reallocarray strlcat strlcpy])
58
59# If the first PKG_CHECK_MODULES appears inside a conditional, pkg-config
60# must first be located explicitly.
61PKG_PROG_PKG_CONFIG
62
63#
64# select libraries to include
65#
66
67XFONT_FONTFILE=no
68
69#
70# FreeType for all scalable (OpenType, TrueType, PostScript) and
71# some bitmap formats (BDF & PCF)
72#
73AC_ARG_ENABLE(freetype,
74	AS_HELP_STRING([--disable-freetype],
75		[Build freetype backend (default: enabled)]),
76	[XFONT_FREETYPE=$enableval],[XFONT_FREETYPE=yes])
77AM_CONDITIONAL(XFONT_FREETYPE, [test x$XFONT_FREETYPE = xyes])
78if test x$XFONT_FREETYPE = xyes; then
79	AC_DEFINE(XFONT_FREETYPE,1,[Support FreeType rasterizer for nearly all font file formats])
80	AC_ARG_WITH(freetype-config,
81		AS_HELP_STRING([--with-freetype-config=PROG],
82			[Use FreeType configuration program PROG]),
83		[freetype_config=$withval], [freetype_config=auto])
84
85	if test "$freetype_config" = "auto" ; then
86		PKG_CHECK_MODULES(FREETYPE, freetype2,
87			freetype_config=no, freetype_config=yes)
88	fi
89
90	if test "$freetype_config" = "yes"; then
91		AC_PATH_PROG(ft_config,freetype-config,no)
92		if test "$ft_config" = "no"; then
93			AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
94		fi
95	else
96		ft_config="$freetype_config"
97	fi
98
99	if test "$freetype_config" != "no"; then
100		FREETYPE_CFLAGS="`$ft_config --cflags`"
101		FREETYPE_LIBS="`$ft_config --libs`"
102	fi
103	FREETYPE_REQUIRES="freetype2"
104	XFONT_FONTFILE=yes
105else
106	FREETYPE_CFLAGS=""
107	FREETYPE_LIBS=""
108	FREETYPE_REQUIRES=""
109fi
110AC_SUBST(FREETYPE_LIBS)
111AC_SUBST(FREETYPE_CFLAGS)
112AC_SUBST(FREETYPE_REQUIRES)
113
114#
115# Bitmap fonts in files:
116#	Builtins (gzipped pcf format in .text segment)
117#	PCF
118#	BDF
119#	SNF
120#
121
122AC_DEFINE(X_GZIP_FONT_COMPRESSION,1,[Support gzip for bitmap fonts])
123X_GZIP_FONT_COMPRESSION=1
124AC_SUBST(X_GZIP_FONT_COMPRESSION)
125AC_CHECK_LIB(z, gzopen, [Z_LIBS=-lz], AC_MSG_ERROR([*** zlib is required]))
126
127AC_ARG_WITH(bzip2,
128	AS_HELP_STRING([--with-bzip2],
129	  [Use libbz2 to support bzip2 compressed bitmap fonts (default: no)]),
130	[], [with_bzip2=no])
131if test "x$with_bzip2" = xyes; then
132	AC_CHECK_LIB(bz2, BZ2_bzopen, [Z_LIBS="$Z_LIBS -lbz2"],
133		AC_MSG_ERROR([*** libbz2 is required for bzip2 support]))
134	AC_DEFINE(X_BZIP2_FONT_COMPRESSION,1,[Support bzip2 for bitmap fonts])
135fi
136AM_CONDITIONAL(X_BZIP2_FONT_COMPRESSION, [test "x$with_bzip2" = xyes ])
137AC_SUBST(Z_LIBS)
138
139AC_ARG_ENABLE(builtins,
140	AS_HELP_STRING([--disable-builtins],
141		[Support builtin fonts (default: enabled)]),
142	[XFONT_BUILTINS=$enableval], [XFONT_BUILTINS=yes])
143AM_CONDITIONAL(XFONT_BUILTINS, [test "x$XFONT_BUILTINS" = xyes ])
144if test "x$XFONT_BUILTINS" = xyes; then
145	AC_DEFINE(XFONT_BUILTINS,1,[Support built-in fonts])
146	XFONT_BITMAP=yes
147fi
148
149AC_ARG_ENABLE(pcfformat,
150	AS_HELP_STRING([--disable-pcfformat],
151		[Support PCF format bitmap fonts (default: enabled)]),
152	[XFONT_PCFFORMAT=$enableval], [XFONT_PCFFORMAT=yes])
153AM_CONDITIONAL(XFONT_PCFFORMAT, [test "x$XFONT_PCFFORMAT" = xyes])
154if test "x$XFONT_PCFFORMAT" = xyes; then
155	AC_DEFINE(XFONT_PCFFORMAT,1,[Support pcf format bitmap font files])
156	XFONT_BITMAP=yes
157fi
158
159AM_CONDITIONAL(XFONT_PCF_OR_BUILTIN,
160	[test "x$XFONT_PCFFORMAT" = xyes -o "x$XFONT_BUILTINS" = xyes])
161
162AC_ARG_ENABLE(bdfformat,
163	AS_HELP_STRING([--disable-bdfformat],
164		[Support BDF format bitmap fonts (default: enabled)]),
165	[XFONT_BDFFORMAT=$enableval], [XFONT_BDFFORMAT=yes])
166AM_CONDITIONAL(XFONT_BDFFORMAT, [test "x$XFONT_BDFFORMAT" = xyes])
167if test "x$XFONT_BDFFORMAT" = xyes; then
168	AC_DEFINE(XFONT_BDFFORMAT,1,[Support bdf format bitmap font files])
169	XFONT_BITMAP=yes
170fi
171
172AC_ARG_ENABLE(snfformat,
173	AS_HELP_STRING([--enable-snfformat],
174		[Support SNF format bitmap fonts (default: disabled)]),
175	[XFONT_SNFFORMAT=$enableval], [XFONT_SNFFORMAT=no])
176AM_CONDITIONAL(XFONT_SNFFORMAT, [test "x$XFONT_SNFFORMAT" = xyes])
177if test "x$XFONT_SNFFORMAT" = xyes; then
178	AC_DEFINE(XFONT_SNFFORMAT,1,[Support snf format bitmap font files])
179	XFONT_BITMAP=yes
180fi
181
182AM_CONDITIONAL(XFONT_BITMAP, [test "x$XFONT_BITMAP" = xyes ])
183if test "x$XFONT_BITMAP" = xyes; then
184	AC_DEFINE(XFONT_BITMAP,1,[Support bitmap font files])
185	XFONT_FONTFILE=yes
186fi
187
188AM_CONDITIONAL(XFONT_FONTFILE, [test "x$XFONT_FONTFILE" = xyes])
189if test "x$XFONT_FONTFILE" = xyes; then
190	AC_DEFINE(XFONT_FONTFILE,1,[Support fonts in files])
191fi
192
193#
194# Support connection to font servers?
195#
196
197AC_ARG_ENABLE(fc,
198	AS_HELP_STRING([--disable-fc],
199		[Support connections to xfs servers (default: enabled)]),
200	[XFONT_FC=$enableval],[XFONT_FC=yes])
201AM_CONDITIONAL(XFONT_FC, [test "x$XFONT_FC" = xyes])
202if test "x$XFONT_FC" = xyes; then
203	AC_DEFINE(XFONT_FC,1,[Support the X Font Services Protocol])
204fi
205
206
207AC_CHECK_LIB(m, hypot, [MATH_LIBS=-lm
208AC_SUBST(MATH_LIBS)], AC_MSG_ERROR([*** libm is required]))
209
210PKG_CHECK_MODULES(XFONT, [xproto xtrans fontsproto >= 2.1.3 fontenc])
211
212# Transport selection macro from xtrans.m4
213XTRANS_CONNECTION_FLAGS
214
215case $host_os in
216    linux*)
217        OS_CFLAGS="-D_XOPEN_SOURCE"
218        ;;
219    *)
220        OS_CFLAGS=
221        ;;
222esac
223
224save_CFLAGS="$CFLAGS"
225CFLAGS="$CFLAGS -fvisibility=hidden"
226CFLAGS_VISIBILITY=
227AC_COMPILE_IFELSE(
228  [AC_LANG_SOURCE([[
229    #if defined(__CYGWIN__) || defined(__MINGW32__)
230    #error No visibility support
231    #endif
232    extern __attribute__((__visibility__("default"))) int x;
233  ]])],
234  [CFLAGS_VISIBILITY=-fvisibility=hidden],
235  []
236)
237CFLAGS="$save_CFLAGS"
238OS_CFLAGS="$OS_CFLAGS $CFLAGS_VISIBILITY"
239
240AC_SUBST([OS_CFLAGS])
241
242AC_CONFIG_FILES([Makefile
243		doc/Makefile
244		xfont2.pc])
245AC_OUTPUT
246