configure.ac revision 245c37e9 
1dnl Process this file with autoconf to produce a configure script.
2
3# Initialize Autoconf
4AC_PREREQ([2.60])
5AC_INIT([libxcb],[1.13],
6        [https://bugs.freedesktop.org/enter_bug.cgi?product=xcb],
7        [libxcb])
8AC_CONFIG_AUX_DIR([build-aux])
9AC_CONFIG_MACRO_DIR([m4])
10AC_CONFIG_SRCDIR([xcb.pc.in])
11AC_CONFIG_HEADERS([src/config.h])
12
13# Initialize Automake
14AM_INIT_AUTOMAKE([foreign dist-bzip2])
15AM_PATH_PYTHON([2.6])
16
17# Set common system defines for POSIX extensions, such as _GNU_SOURCE
18# Must be called before any macros that run the compiler (like AC_PROG_LIBTOOL)
19# to avoid autoconf errors.
20AC_USE_SYSTEM_EXTENSIONS
21
22# Initialize libtool
23LT_PREREQ([2.2])
24LT_INIT([win32-dll])
25
26# Require xorg-macros minimum of 1.18 - Initial version
27m4_ifndef([XORG_MACROS_VERSION],
28          [m4_fatal([must install xorg-macros 1.18 or later before running autoconf/autogen])])
29XORG_MACROS_VERSION(1.18)
30XORG_DEFAULT_OPTIONS
31XORG_ENABLE_DEVEL_DOCS
32XORG_WITH_DOXYGEN
33
34# The dot drawing tool is checked by XORG_WITH_DOXYGEN, needed for xcb manual
35if test x"$HAVE_DOT" = xno; then
36    AC_MSG_WARN([dot not found - doxygen targets will be skipped])
37fi
38
39PKG_CHECK_MODULES(CHECK, [check >= 0.9.4], [HAVE_CHECK=yes], [HAVE_CHECK=no])
40AM_CONDITIONAL(HAVE_CHECK, test x$HAVE_CHECK = xyes)
41
42XSLTPROC=no
43HTML_CHECK_RESULT=no
44if test x"$HAVE_CHECK" = xyes; then
45        AC_PATH_PROG(XSLTPROC, xsltproc, no)
46        if test x"$XSLTPROC" != xno; then
47                HTML_CHECK_RESULT=yes
48        fi
49fi
50AC_SUBST(HTML_CHECK_RESULT)
51
52# Checks for pkg-config packages
53PKG_CHECK_MODULES(XCBPROTO, xcb-proto >= 1.13)
54NEEDED="pthread-stubs xau >= 0.99.2"
55PKG_CHECK_MODULES(NEEDED, $NEEDED)
56
57have_xdmcp="no"
58PKG_CHECK_MODULES(XDMCP, xdmcp,
59        AC_CHECK_LIB(Xdmcp, XdmcpWrap,
60                [
61                AC_DEFINE(HASXDMAUTH,1,[Has Wraphelp.c needed for XDM AUTH protocols])
62                NEEDED="$NEEDED xdmcp"
63                have_xdmcp="yes"
64                ],
65                [
66                XDMCP_CFLAGS=
67                XDMCP_LIBS=
68                ], [$XDMCP_LIBS]),
69        [AC_MSG_RESULT(no)])
70
71AC_SUBST(NEEDED)
72
73# Find the xcb-proto protocol descriptions
74AC_MSG_CHECKING(XCBPROTO_XCBINCLUDEDIR)
75XCBPROTO_XCBINCLUDEDIR=`$PKG_CONFIG --variable=xcbincludedir xcb-proto`
76AC_MSG_RESULT($XCBPROTO_XCBINCLUDEDIR)
77AC_SUBST(XCBPROTO_XCBINCLUDEDIR)
78
79# Find the xcb-proto version
80XCBPROTO_VERSION=`$PKG_CONFIG --modversion xcb-proto`
81AC_SUBST(XCBPROTO_VERSION)
82
83# Find the xcbgen Python package
84AC_MSG_CHECKING(XCBPROTO_XCBPYTHONDIR)
85XCBPROTO_XCBPYTHONDIR=`$PKG_CONFIG --variable=pythondir xcb-proto`
86AC_MSG_RESULT($XCBPROTO_XCBPYTHONDIR)
87AC_SUBST(XCBPROTO_XCBPYTHONDIR)
88
89AC_HEADER_STDC
90AC_SEARCH_LIBS(getaddrinfo, socket)
91AC_SEARCH_LIBS(connect, socket)
92
93# Find support for sending a message from a socket
94AC_SEARCH_LIBS(sendmsg, socket, [have_sendmsg="yes"], [have_sendmsg="no"])
95
96# XPG4v2/UNIX95 added msg_control - check to see if we need to define
97# _XOPEN_SOURCE to get it (such as on Solaris)
98AC_CHECK_MEMBER([struct msghdr.msg_control], [], [],
99                 [
100AC_INCLUDES_DEFAULT
101#include <sys/socket.h>
102                 ])
103# First try for Solaris in C99 compliant mode, which requires XPG6/UNIX03
104if test "x$ac_cv_member_struct_msghdr_msg_control" = xno; then
105    unset ac_cv_member_struct_msghdr_msg_control
106    AC_MSG_NOTICE([trying again with _XOPEN_SOURCE=600])
107    AC_CHECK_MEMBER([struct msghdr.msg_control],
108                    [AC_DEFINE([_XOPEN_SOURCE], [600],
109                       [Defined if needed to expose struct msghdr.msg_control])
110                    ], [], [
111#define _XOPEN_SOURCE 600
112AC_INCLUDES_DEFAULT
113#include <sys/socket.h>
114                     ])
115fi
116# If that didn't work, fall back to XPG5/UNIX98 with C89
117if test "x$ac_cv_member_struct_msghdr_msg_control" = xno; then
118    unset ac_cv_member_struct_msghdr_msg_control
119    AC_MSG_NOTICE([trying again with _XOPEN_SOURCE=500])
120    AC_CHECK_MEMBER([struct msghdr.msg_control],
121                    [AC_DEFINE([_XOPEN_SOURCE], [500],
122                       [Defined if needed to expose struct msghdr.msg_control])
123                    ], [have_sendmsg="no"], [
124#define _XOPEN_SOURCE 500
125AC_INCLUDES_DEFAULT
126#include <sys/socket.h>
127                     ])
128fi
129
130case x$have_sendmsg in
131xyes)
132        AC_DEFINE([HAVE_SENDMSG],1,[Define if your platform supports sendmsg])
133        ;;
134esac
135
136have_win32="no"
137lt_enable_auto_import=""
138case $host_os in
139mingw*)
140        have_win32="yes"
141        lt_enable_auto_import="-Wl,--enable-auto-import"
142        ;;
143linux*)
144        AC_DEFINE([HAVE_ABSTRACT_SOCKETS], 1, [Define if your platform supports abstract sockets])
145        ;;
146esac
147
148AC_SUBST(lt_enable_auto_import)
149AM_CONDITIONAL([XCB_HAVE_WIN32], [test "x${have_win32}" = "xyes"])
150
151dnl define buffer queue size
152AC_ARG_WITH([queue-size],
153            AS_HELP_STRING([--with-queue-size=SIZE],
154            [Set the XCB buffer queue size (default is 16384)]),
155            [xcb_queue_buffer_size="$withval"],
156            [xcb_queue_buffer_size=16384])
157AC_DEFINE_UNQUOTED(XCB_QUEUE_BUFFER_SIZE, [$xcb_queue_buffer_size],
158                   [XCB buffer queue size])
159
160dnl check for the sockaddr_un.sun_len member
161AC_CHECK_MEMBER([struct sockaddr_un.sun_len],
162                [AC_DEFINE(HAVE_SOCKADDR_SUN_LEN,1,[Have the sockaddr_un.sun_len member.])],
163                [],
164                [ #include <sys/types.h>
165                  #include <sys/un.h>
166                ])
167
168dnl check for support for Solaris Trusted Extensions
169AC_CHECK_HEADERS([tsol/label.h])
170AC_CHECK_FUNCS([is_system_labeled])
171
172dnl check for IOV_MAX, and fall back to UIO_MAXIOV on BSDish systems
173AC_CHECK_DECL([IOV_MAX], [],
174              [AC_CHECK_DECL([UIO_MAXIOV], [AC_DEFINE([IOV_MAX], [UIO_MAXIOV])],
175                                           [AC_DEFINE([IOV_MAX], [16], [Define if not provided by <limits.h>])],
176                                           [[#include <sys/uio.h>]])],
177              [[#include <limits.h>]])
178
179xcbincludedir='${includedir}/xcb'
180AC_SUBST(xcbincludedir)
181
182XCB_CHECK_VISIBILITY()
183
184AC_CHECK_FUNC(getaddrinfo, [AC_DEFINE(HAVE_GETADDRINFO, 1, [getaddrinfo() function is available])], )
185
186case $host_os in
187        # darwin through Snow Leopard has poll() but can't be used to poll character devices.
188        darwin@<:@789@:>@*|darwin10*) ;;
189        darwin*)
190                _ac_xorg_macosx_version_min=""
191                if echo $CPPFLAGS $CFLAGS | grep -q mmacosx-version-min ; then
192                        _ac_xorg_macosx_version_min=`echo $CPPFLAGS $CFLAGS | sed 's/^.*-mmacosx-version-min=\(@<:@^ @:>@*\).*$/\1/'`
193                else
194                        _ac_xorg_macosx_version_min=$MACOSX_DEPLOYMENT_TARGET
195                fi
196                case $_ac_xorg_macosx_version_min in
197                        10.@<:@0123456@:>@|10.@<:@0123456@:>@.*) ;;
198                        *)
199                                AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
200                        ;;
201                esac
202                unset _ac_xorg_macosx_version_min
203                ;;
204        *)
205                AC_CHECK_FUNC(poll, [AC_DEFINE(USE_POLL, 1, [poll() function is available])], )
206        ;;
207esac
208
209dnl Link with winsock for socket functions on MinGW
210case $host_os in
211        *mingw*)
212                AC_CHECK_LIB([ws2_32],[main])
213                ;;
214        *)
215                ;;
216esac
217
218XCB_EXTENSION(Composite, yes)
219XCB_EXTENSION(Damage, yes)
220XCB_EXTENSION(DPMS, yes)
221XCB_EXTENSION(DRI2, yes)
222XCB_EXTENSION(DRI3, $have_sendmsg)
223XCB_EXTENSION(GE, no)
224XCB_EXTENSION(GLX, yes)
225XCB_EXTENSION(Present, yes)
226XCB_EXTENSION(RandR, yes)
227XCB_EXTENSION(Record, yes)
228XCB_EXTENSION(Render, yes)
229XCB_EXTENSION(Resource, yes)
230XCB_EXTENSION(Screensaver, yes)
231XCB_EXTENSION(Shape, yes)
232XCB_EXTENSION(Shm, yes)
233XCB_EXTENSION(Sync, yes)
234XCB_EXTENSION(Xevie, no)
235XCB_EXTENSION(XFixes, yes)
236XCB_EXTENSION(XFree86-DRI, yes)
237XCB_EXTENSION(Xinerama, yes)
238XCB_EXTENSION(XInput, yes)
239XCB_EXTENSION(XKB, yes)
240XCB_EXTENSION(Xprint, no)
241XCB_EXTENSION(SELinux, no)
242XCB_EXTENSION(XTest, yes)
243XCB_EXTENSION(Xv, yes)
244XCB_EXTENSION(XvMC, yes)
245
246AC_ARG_WITH(launchd, AS_HELP_STRING([--with-launchd], [Build with support for Apple's launchd (default: auto)]), [LAUNCHD=$withval], [LAUNCHD=auto])
247if test "x$LAUNCHD" = xauto; then
248        unset LAUNCHD
249        AC_CHECK_PROG(LAUNCHD, [launchd], [yes], [no], [$PATH$PATH_SEPARATOR/sbin])
250fi
251
252if test "x$LAUNCHD" = xyes ; then
253        AC_DEFINE(HAVE_LAUNCHD, 1, [launchd support available])
254fi
255
256AC_ARG_WITH(serverside-support, AS_HELP_STRING([--with-serverside-support], [Build with support for server-side usage of xcb. This is still EXPERIMENTAL! ABI/API may change! (default: no)]), [XCB_SERVERSIDE_SUPPORT=$withval], [XCB_SERVERSIDE_SUPPORT=no])
257
258AM_CONDITIONAL(XCB_SERVERSIDE_SUPPORT, test "x$XCB_SERVERSIDE_SUPPORT" = "xyes")
259
260AC_CONFIG_FILES([
261Makefile
262doc/Makefile
263man/Makefile
264src/Makefile
265tests/Makefile
266])
267
268AC_CONFIG_FILES([
269xcb.pc
270xcb-composite.pc
271xcb-damage.pc
272xcb-dpms.pc
273xcb-dri2.pc
274xcb-dri3.pc
275xcb-ge.pc
276xcb-glx.pc
277xcb-present.pc
278xcb-randr.pc
279xcb-record.pc
280xcb-render.pc
281xcb-res.pc
282xcb-screensaver.pc
283xcb-shape.pc
284xcb-shm.pc
285xcb-sync.pc
286xcb-xevie.pc
287xcb-xf86dri.pc
288xcb-xfixes.pc
289xcb-xinerama.pc
290xcb-xinput.pc
291xcb-xkb.pc
292xcb-xprint.pc
293xcb-xselinux.pc
294xcb-xtest.pc
295xcb-xv.pc
296xcb-xvmc.pc
297])
298
299AC_CONFIG_FILES([
300doc/xcb.doxygen
301])
302
303AC_OUTPUT
304
305dnl Configuration output
306
307echo ""
308echo "  Package: ${PACKAGE_NAME} ${PACKAGE_VERSION}"
309echo ""
310echo "  Configuration"
311echo "    XDM support.........: ${have_xdmcp}"
312echo "    sendmsg fd passing..: ${have_sendmsg}"
313echo "    Build unit tests....: ${HAVE_CHECK}"
314echo "      with html results.: ${HTML_CHECK_RESULT}"
315echo "    XCB buffer size.....: ${xcb_queue_buffer_size}"
316echo ""
317echo "  X11 extensions"
318echo "    Composite...........: ${BUILD_COMPOSITE}"
319echo "    Damage..............: ${BUILD_DAMAGE}"
320echo "    Dpms................: ${BUILD_DPMS}"
321echo "    Dri2................: ${BUILD_DRI2}"
322echo "    Dri3................: ${BUILD_DRI3}"
323echo "    GenericEvent........: ${BUILD_GE}"
324echo "    Glx.................: ${BUILD_GLX}"
325echo "    Randr...............: ${BUILD_RANDR}"
326echo "    Record..............: ${BUILD_RECORD}"
327echo "    Render..............: ${BUILD_RENDER}"
328echo "    Resource............: ${BUILD_RESOURCE}"
329echo "    Screensaver.........: ${BUILD_SCREENSAVER}"
330echo "    selinux.............: ${BUILD_SELINUX}"
331echo "    Shape...............: ${BUILD_SHAPE}"
332echo "    Shm.................: ${BUILD_SHM}"
333echo "    Sync................: ${BUILD_SYNC}"
334echo "    Xevie...............: ${BUILD_XEVIE}"
335echo "    Xfixes..............: ${BUILD_XFIXES}"
336echo "    Xfree86-dri.........: ${BUILD_XFREE86_DRI}"
337echo "    xinerama............: ${BUILD_XINERAMA}"
338echo "    xinput..............: ${BUILD_XINPUT}"
339echo "    xkb.................: ${BUILD_XKB}"
340echo "    xprint..............: ${BUILD_XPRINT}"
341echo "    xtest...............: ${BUILD_XTEST}"
342echo "    xv..................: ${BUILD_XV}"
343echo "    xvmc................: ${BUILD_XVMC}"
344echo ""
345echo "  Used CFLAGS:"
346echo "    CPPFLAGS............: ${CPPFLAGS}"
347echo "    CFLAGS..............: ${CFLAGS}"
348echo ""
349echo "  Installation:"
350echo "    Prefix..............: ${prefix}"
351echo ""
352