configure.ac revision d6c0b56e 
1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23# Initialize Autoconf
24AC_PREREQ([2.60])
25AC_INIT([xf86-video-amdgpu],
26        [1.1.0],
27        [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
28        [xf86-video-amdgpu])
29
30AC_CONFIG_SRCDIR([Makefile.am])
31AC_CONFIG_HEADERS([config.h])
32
33AC_CONFIG_AUX_DIR(.)
34
35# Initialize Automake
36AM_INIT_AUTOMAKE([foreign dist-bzip2])
37AC_SYS_LARGEFILE
38
39AM_MAINTAINER_MODE
40
41# Require X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
42m4_ifndef([XORG_MACROS_VERSION],
43          [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
44XORG_MACROS_VERSION(1.8)
45XORG_DEFAULT_OPTIONS
46
47# Initialize libtool
48AC_DISABLE_STATIC
49AC_PROG_LIBTOOL
50
51# Checks for programs.
52AM_PROG_CC_C_O
53
54if test "x$GCC" = "xyes"; then
55	CPPFLAGS="$CPPFLAGS -Wall"
56fi
57
58AH_TOP([#include "xorg-server.h"])
59
60# Define a configure option for an alternate module directory
61AC_ARG_WITH(xorg-module-dir,
62            AS_HELP_STRING([--with-xorg-module-dir=DIR],
63                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
64            [moduledir="$withval"],
65            [moduledir="$libdir/xorg/modules"])
66
67# Store the list of server defined optional extensions in REQUIRED_MODULES
68XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
69XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
70XORG_DRIVER_CHECK_EXT(XV, videoproto)
71XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
72
73# Checks for libraries.
74PKG_CHECK_MODULES(LIBDRM, [libdrm >= 2.4.58])
75PKG_CHECK_MODULES(LIBDRM_AMDGPU, [libdrm_amdgpu])
76PKG_CHECK_MODULES(GBM, [gbm])
77
78# Obtain compiler/linker options for the driver dependencies
79PKG_CHECK_MODULES(XORG, [xorg-server >= 1.9 xproto fontsproto xf86driproto $REQUIRED_MODULES])
80PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
81                  HAVE_XEXTPROTO_71="yes"; AC_DEFINE(HAVE_XEXTPROTO_71, 1, [xextproto 7.1 available]),
82                  HAVE_XEXTPROTO_71="no")
83AM_CONDITIONAL(HAVE_XEXTPROTO_71, [ test "$HAVE_XEXTPROTO_71" = "yes" ])
84
85# Define a configure option for an alternate X Server configuration directory
86# Section "OutputClass" is only supported as of xserver 1.16
87PKG_CHECK_EXISTS([xorg-server >= 1.16],
88		 [sysconfigdir=`$PKG_CONFIG --variable=sysconfigdir xorg-server`],
89		 [sysconfigdir=""])
90AC_ARG_WITH(xorg-conf-dir,
91            AS_HELP_STRING([--with-xorg-conf-dir=DIR],
92                           [Default xorg.conf.d directory [[default=from $PKG_CONFIG xorg-server]]]),
93            [configdir="$withval"],
94            [configdir="$sysconfigdir"])
95AC_SUBST(configdir)
96AM_CONDITIONAL(HAS_XORG_CONF_DIR, [test "x$sysconfigdir" != "x"])
97
98AC_ARG_ENABLE([udev],
99		AS_HELP_STRING([--disable-udev], [Disable libudev support [default=auto]]),
100		[enable_udev="$enableval"],
101		[enable_udev=auto])
102if test "x$enable_udev" != "xno"; then
103	PKG_CHECK_MODULES(LIBUDEV, [libudev], [LIBUDEV=yes], [LIBUDEV=no])
104	if test "x$LIBUDEV" = xyes; then
105		AC_DEFINE(HAVE_LIBUDEV, 1,[libudev support])
106	elif test "x$enable_udev" != "xauto"; then
107		AC_MSG_ERROR([Building with udev requested but libudev not found])
108	fi
109fi
110AM_CONDITIONAL(LIBUDEV, test x$LIBUDEV = xyes)
111
112SAVE_CPPFLAGS="$CPPFLAGS"
113CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
114
115AC_MSG_CHECKING([whether to include GLAMOR support])
116AC_ARG_ENABLE(glamor,
117	      AS_HELP_STRING([--disable-glamor],
118			     [Disable glamor, a new GL-based acceleration [default=enabled]]),
119	      [GLAMOR="$enableval"],
120	      [GLAMOR=yes])
121
122if test "x$GLAMOR" != "xno"; then
123	AC_CHECK_HEADERS([glamor.h], [GLAMOR_H="yes"], [GLAMOR_H="no"], [#include "xorg-server.h"])
124
125	if test "x$GLAMOR_H" = xyes; then
126		AC_CHECK_DECL(GLAMOR_NO_DRI3,
127			      [GLAMOR_XSERVER="yes"], [GLAMOR_XSERVER="no"],
128			      [#include "xorg-server.h"
129			       #include "glamor.h"])
130
131		AC_CHECK_DECL(glamor_glyphs_init,
132			      [AC_DEFINE(HAVE_GLAMOR_GLYPHS_INIT, 1,
133					 [Have glamor_glyphs_init API])], [],
134			      [#include "xorg-server.h"
135			       #include "glamor.h"])
136
137		AC_CHECK_DECL(glamor_egl_destroy_textured_pixmap,
138			      [AC_DEFINE(HAVE_GLAMOR_EGL_DESTROY_TEXTURED_PIXMAP, 1,
139					 [Have glamor_egl_destroy_textured_pixmap API])], [],
140			      [#include "xorg-server.h"
141			       #include "glamor.h"])
142	fi
143
144	PKG_CHECK_MODULES(LIBGL, [gl])
145
146	if test "x$GLAMOR_XSERVER" != xyes; then
147		PKG_CHECK_MODULES(LIBGLAMOR, [glamor >= 0.6.0])
148		PKG_CHECK_MODULES(LIBGLAMOR_EGL, [glamor-egl])
149	fi
150	AC_DEFINE(USE_GLAMOR, 1, [Enable glamor acceleration])
151else
152	AC_MSG_RESULT([$GLAMOR])
153fi
154AM_CONDITIONAL(GLAMOR, test x$GLAMOR != xno)
155
156AC_CHECK_DECL(fbGlyphs,
157	      [AC_DEFINE(HAVE_FBGLYPHS, 1, [Have fbGlyphs API])], [],
158	      [#include <X11/Xmd.h>
159	       #include <X11/Xfuncproto.h>
160	       #include <X11/extensions/renderproto.h>
161	       #include <xorg-server.h>
162	       #include <picture.h>
163	       #include <glyphstr.h>
164	       #include <fbpict.h>])
165
166AC_CHECK_DECL(xf86CursorResetCursor,
167	      [AC_DEFINE(HAVE_XF86_CURSOR_RESET_CURSOR, 1,
168	      [Have xf86CursorResetCursor API])], [],
169	      [#include <xorg-server.h>
170	       #include <xf86Cursor.h>])
171
172AC_CHECK_DECL(xorg_list_init,
173	      [AC_DEFINE(HAVE_XORG_LIST, 1, [Have xorg_list API])], [],
174	      [#include <X11/Xdefs.h>
175	      #include "xorg-server.h"
176	      #include "list.h"])
177
178AC_CHECK_DECL(GBM_BO_USE_LINEAR,
179	      [AC_DEFINE(HAVE_GBM_BO_USE_LINEAR, 1, [Have GBM_BO_USE_LINEAR])], [],
180	      [#include <stdlib.h>
181	       #include <gbm.h>])
182
183AC_CHECK_HEADERS([misyncshm.h], [], [],
184                 [#include <X11/Xdefs.h>
185	          #include <X11/Xfuncproto.h>
186	          #include <xorg-server.h>
187		  #include <screenint.h>])
188
189AC_CHECK_HEADERS([present.h], [], [],
190		 [#include <X11/Xmd.h>
191		 #include <X11/Xproto.h>
192		 #include <X11/X.h>
193		 #include "xorg-server.h"])
194
195AC_CHECK_HEADERS([dri3.h], [], [],
196		 [#include <X11/Xmd.h>
197		 #include <xorg-server.h>])
198
199CPPFLAGS="$SAVE_CPPFLAGS"
200
201# Checks for headers/macros for byte swapping
202# Known variants:
203#	<byteswap.h> bswap_16, bswap_32, bswap_64  (glibc)
204#	<sys/endian.h> __swap16, __swap32, __swap64 (OpenBSD)
205#	<sys/endian.h> bswap16, bswap32, bswap64 (other BSD's)
206#	and a fallback to local macros if none of the above are found
207
208# if <byteswap.h> is found, assume it's the correct version
209AC_CHECK_HEADERS([byteswap.h])
210
211# if <sys/endian.h> is found, have to check which version
212AC_CHECK_HEADER([sys/endian.h], [HAVE_SYS_ENDIAN_H="yes"], [HAVE_SYS_ENDIAN_H="no"])
213
214if test "x$HAVE_SYS_ENDIAN_H" = "xyes" ; then
215	AC_MSG_CHECKING([for __swap16 variant of <sys/endian.h> byteswapping macros])
216	AC_LINK_IFELSE([AC_LANG_PROGRAM([
217#include <sys/types.h>
218#include <sys/endian.h>
219 ], [
220int a = 1, b;
221b = __swap16(a);
222 ])
223], [SYS_ENDIAN__SWAP='yes'], [SYS_ENDIAN__SWAP='no'])
224	AC_MSG_RESULT([$SYS_ENDIAN__SWAP])
225
226	AC_MSG_CHECKING([for bswap16 variant of <sys/endian.h> byteswapping macros])
227	AC_LINK_IFELSE([AC_LANG_PROGRAM([
228#include <sys/types.h>
229#include <sys/endian.h>
230 ], [
231int a = 1, b;
232b = bswap16(a);
233 ])
234], [SYS_ENDIAN_BSWAP='yes'], [SYS_ENDIAN_BSWAP='no'])
235	AC_MSG_RESULT([$SYS_ENDIAN_BSWAP])
236
237    	if test "$SYS_ENDIAN_BSWAP" = "yes" ; then
238		USE_SYS_ENDIAN_H=yes
239		BSWAP=bswap
240	else	
241	    	if test "$SYS_ENDIAN__SWAP" = "yes" ; then
242			USE_SYS_ENDIAN_H=yes
243			BSWAP=__swap
244		else
245			USE_SYS_ENDIAN_H=no
246		fi
247	fi
248
249	if test "$USE_SYS_ENDIAN_H" = "yes" ; then
250	    AC_DEFINE([USE_SYS_ENDIAN_H], 1, 
251		[Define to use byteswap macros from <sys/endian.h>])
252	    AC_DEFINE_UNQUOTED([bswap_16], ${BSWAP}16, 
253			[Define to 16-bit byteswap macro])
254	    AC_DEFINE_UNQUOTED([bswap_32], ${BSWAP}32, 
255			[Define to 32-bit byteswap macro])
256	    AC_DEFINE_UNQUOTED([bswap_64], ${BSWAP}64, 
257			[Define to 64-bit byteswap macro])
258	fi
259fi
260
261AC_SUBST([moduledir])
262
263DRIVER_NAME=amdgpu
264AC_SUBST([DRIVER_NAME])
265
266AC_CONFIG_FILES([
267                Makefile
268                src/Makefile
269                man/Makefile
270                conf/Makefile
271])
272AC_OUTPUT
273
274dnl
275dnl Output some configuration info for the user
276dnl
277echo ""
278echo "        prefix:              $prefix"
279echo "        exec_prefix:         $exec_prefix"
280echo "        libdir:              $libdir"
281echo "        includedir:          $includedir"
282
283echo ""
284echo "        CFLAGS:              $CFLAGS"
285echo "        CXXFLAGS:            $CXXFLAGS"
286echo "        Macros:              $DEFINES"
287
288echo ""
289echo "        Run '${MAKE-make}' to build xf86-video-amdgpu"
290echo ""
291