configure.ac revision 1fd23544 
1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23AC_PREREQ(2.57)
24AC_INIT([xf86-video-sis],
25        0.10.1,
26        [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
27        xf86-video-sis)
28
29AC_CONFIG_SRCDIR([Makefile.am])
30AM_CONFIG_HEADER([config.h])
31AC_CONFIG_AUX_DIR(.)
32
33AM_INIT_AUTOMAKE([dist-bzip2])
34
35AM_MAINTAINER_MODE
36
37# Checks for programs.
38AC_DISABLE_STATIC
39AC_PROG_LIBTOOL
40AC_PROG_CC
41XORG_PROG_RAWCPP
42
43AH_TOP([#include "xorg-server.h"])
44
45AC_ARG_WITH(xorg-module-dir,
46            AC_HELP_STRING([--with-xorg-module-dir=DIR],
47                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
48            [moduledir="$withval"],
49            [moduledir="$libdir/xorg/modules"])
50
51AC_ARG_ENABLE(dri, AC_HELP_STRING([--disable-dri],
52                                  [Disable DRI support [[default=auto]]]),
53              [DRI="$enableval"],
54              [DRI=auto])
55
56# Checks for extensions
57XORG_DRIVER_CHECK_EXT(XINERAMA, xineramaproto)
58XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
59XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
60XORG_DRIVER_CHECK_EXT(XV, videoproto)
61XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
62
63# Checks for pkg-config packages
64PKG_CHECK_MODULES(XORG, [xorg-server >= 1.0.99.901 xproto fontsproto xf86dgaproto $REQUIRED_MODULES])
65sdkdir=$(pkg-config --variable=sdkdir xorg-server)
66
67# Checks for libraries.
68
69# Checks for header files.
70AC_HEADER_STDC
71
72if test "$DRI" != no; then
73        AC_CHECK_FILE([${sdkdir}/dri.h],
74                      [have_dri_h="yes"], [have_dri_h="no"])
75        AC_CHECK_FILE([${sdkdir}/sarea.h],
76                      [have_sarea_h="yes"], [have_sarea_h="no"])
77        AC_CHECK_FILE([${sdkdir}/dristruct.h],
78                      [have_dristruct_h="yes"], [have_dristruct_h="no"])
79fi
80
81AC_MSG_CHECKING([whether to include DRI support])
82if test x$DRI = xauto; then
83        if test "$have_dri_h" = yes -a \
84                "$have_sarea_h" = yes -a \
85                "$have_dristruct_h" = yes; then
86                DRI="yes"
87        else
88                DRI="no"
89        fi
90fi
91AC_MSG_RESULT([$DRI])
92
93AM_CONDITIONAL(DRI, test x$DRI = xyes)
94if test "$DRI" = yes; then
95        PKG_CHECK_MODULES(DRI, [libdrm >= 2.0 xf86driproto])
96        AC_DEFINE(XF86DRI,1,[Enable DRI driver support])
97        AC_DEFINE(XF86DRI_DEVEL,1,[Enable developmental DRI driver support])
98fi
99
100# technically this should be a configure flag.  meh.
101AC_DEFINE(XF86EXA, 1, [Build support for Exa])
102
103SAVE_CPPFLAGS="$CPPFLAGS"
104CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
105AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
106              [XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
107              [#include "xorg-server.h"])
108CPPFLAGS="$SAVE_CPPFLAGS"
109
110if test "x$XSERVER_LIBPCIACCESS" = xyes; then
111    PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.10])
112    XORG_CFLAGS="$XORG_CFLAGS $PCIACCESS_CFLAGS"
113fi
114AM_CONDITIONAL(XSERVER_LIBPCIACCESS, test "x$XSERVER_LIBPCIACCESS" = xyes)
115
116AC_SUBST([DRI_CFLAGS])
117AC_SUBST([XORG_CFLAGS])
118AC_SUBST([moduledir])
119
120DRIVER_NAME=sis
121AC_SUBST([DRIVER_NAME])
122
123XORG_MANPAGE_SECTIONS
124XORG_RELEASE_VERSION
125
126XORG_CHECK_LINUXDOC
127
128AC_OUTPUT([
129	Makefile
130	src/Makefile
131	man/Makefile
132])
133