configure.ac revision 93d9adc1 
1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23# Initialize Autoconf
24AC_PREREQ([2.60])
25AC_INIT([xf86-video-sis],
26        [0.10.9],
27        [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
28        [xf86-video-sis])
29AC_CONFIG_SRCDIR([Makefile.am])
30AC_CONFIG_HEADERS([config.h])
31AC_CONFIG_AUX_DIR(.)
32
33# Initialize Automake
34AM_INIT_AUTOMAKE([foreign dist-bzip2])
35AM_MAINTAINER_MODE
36
37# Require X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
38m4_ifndef([XORG_MACROS_VERSION],
39          [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
40XORG_MACROS_VERSION(1.8)
41XORG_DEFAULT_OPTIONS
42
43# Initialize libtool
44AC_DISABLE_STATIC
45AC_PROG_LIBTOOL
46
47AH_TOP([#include "xorg-server.h"])
48
49# Define a configure option for an alternate module directory
50AC_ARG_WITH(xorg-module-dir,
51            AS_HELP_STRING([--with-xorg-module-dir=DIR],
52                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
53            [moduledir="$withval"],
54            [moduledir="$libdir/xorg/modules"])
55
56AC_ARG_ENABLE(dri, AS_HELP_STRING([--disable-dri],
57                                  [Disable DRI support [[default=auto]]]),
58              [DRI="$enableval"],
59              [DRI=auto])
60
61# Store the list of server defined optional extensions in REQUIRED_MODULES
62XORG_DRIVER_CHECK_EXT(XINERAMA, xineramaproto)
63XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
64XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
65XORG_DRIVER_CHECK_EXT(XV, videoproto)
66XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
67
68# Obtain compiler/linker options for the driver dependencies
69PKG_CHECK_MODULES(XORG, [xorg-server >= 1.0.99.901 xproto fontsproto xf86dgaproto >= 2.1 $REQUIRED_MODULES])
70PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
71                  HAVE_XEXTPROTO_71="yes"; AC_DEFINE(HAVE_XEXTPROTO_71, 1, [xextproto 7.1 available]),
72                  HAVE_XEXTPROTO_71="no")
73AM_CONDITIONAL(HAVE_XEXTPROTO_71, [ test "$HAVE_XEXTPROTO_71" = "yes" ])
74sdkdir=`$PKG_CONFIG --variable=sdkdir xorg-server`
75
76# Checks for libraries.
77
78if test "$DRI" != no; then
79        AC_CHECK_FILE([${sdkdir}/dri.h],
80                      [have_dri_h="yes"], [have_dri_h="no"])
81        AC_CHECK_FILE([${sdkdir}/sarea.h],
82                      [have_sarea_h="yes"], [have_sarea_h="no"])
83        AC_CHECK_FILE([${sdkdir}/dristruct.h],
84                      [have_dristruct_h="yes"], [have_dristruct_h="no"])
85fi
86
87AC_MSG_CHECKING([whether to include DRI support])
88if test x$DRI = xauto; then
89        if test "$have_dri_h" = yes -a \
90                "$have_sarea_h" = yes -a \
91                "$have_dristruct_h" = yes; then
92                DRI="yes"
93        else
94                DRI="no"
95        fi
96fi
97AC_MSG_RESULT([$DRI])
98
99AM_CONDITIONAL(DRI, test x$DRI = xyes)
100if test "$DRI" = yes; then
101        PKG_CHECK_MODULES(DRI, [libdrm >= 2.0 xf86driproto])
102        AC_DEFINE(SISDRI,1,[Enable DRI driver support])
103        AC_DEFINE(SISDRI_DEVEL,1,[Enable developmental DRI driver support])
104fi
105
106AC_ARG_ENABLE(xaa,
107              AS_HELP_STRING([--enable-xaa],
108                             [Enable legacy X Acceleration Architecture (XAA) [default=auto]]),
109              [XAA="$enableval"],
110              [XAA=auto])
111if test "x$XAA" != xno; then
112        save_CFLAGS=$CFLAGS
113        save_CPPFLAGS=$CPPFLAGS
114        CFLAGS=$XORG_CFLAGS
115        CPPFLAGS="$XORG_CFLAGS"
116        AC_CHECK_HEADERS([xaa.h], XAA=yes, XAA=no)
117        CFLAGS=$save_CFLAGS
118        CPPFLAGS=$save_CPPFLAGS
119fi
120AC_MSG_CHECKING([whether to include XAA support])
121AM_CONDITIONAL(XAA, test "x$XAA" = xyes)
122AC_MSG_RESULT([$XAA])
123
124# technically this should be a configure flag.  meh.
125AC_DEFINE(XF86EXA, 1, [Build support for Exa])
126
127SAVE_CPPFLAGS="$CPPFLAGS"
128CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
129AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
130              [XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
131              [#include "xorg-server.h"])
132CPPFLAGS="$SAVE_CPPFLAGS"
133
134if test "x$XSERVER_LIBPCIACCESS" = xyes; then
135    PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.12.901])
136    XORG_CFLAGS="$XORG_CFLAGS $PCIACCESS_CFLAGS"
137fi
138AM_CONDITIONAL(XSERVER_LIBPCIACCESS, test "x$XSERVER_LIBPCIACCESS" = xyes)
139
140AC_SUBST([moduledir])
141
142DRIVER_NAME=sis
143AC_SUBST([DRIVER_NAME])
144
145AC_CONFIG_FILES([
146                Makefile
147                src/Makefile
148                man/Makefile
149])
150AC_OUTPUT
151