configure.ac revision 880ed95a 
1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23AC_PREREQ(2.57)
24AC_INIT([xf86-video-tdfx],
25        1.4.1,
26        [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
27        xf86-video-tdfx)
28
29AC_CONFIG_SRCDIR([Makefile.am])
30AM_CONFIG_HEADER([config.h])
31AC_CONFIG_AUX_DIR(.)
32
33AM_INIT_AUTOMAKE([dist-bzip2])
34
35AM_MAINTAINER_MODE
36
37# Checks for programs.
38AC_DISABLE_STATIC
39AC_PROG_LIBTOOL
40AC_PROG_CC
41
42AH_TOP([#include "xorg-server.h"])
43
44AC_ARG_WITH(xorg-module-dir,
45            AC_HELP_STRING([--with-xorg-module-dir=DIR],
46                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
47            [moduledir="$withval"],
48            [moduledir="$libdir/xorg/modules"])
49
50AC_ARG_ENABLE(dri, AC_HELP_STRING([--disable-dri],
51                                  [Disable DRI support [[default=auto]]]),
52              [DRI="$enableval"],
53              [DRI=auto])
54
55# Checks for extensions
56XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
57XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
58XORG_DRIVER_CHECK_EXT(XV, videoproto)
59XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
60
61# Checks for pkg-config packages
62PKG_CHECK_MODULES(XORG, [xorg-server >= 1.0.99.901 xproto fontsproto $REQUIRED_MODULES])
63sdkdir=$(pkg-config --variable=sdkdir xorg-server)
64
65# Checks for libraries.
66SAVE_CPPFLAGS="$CPPFLAGS"
67CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
68AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
69	      [XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
70	      [#include "xorg-server.h"])
71CPPFLAGS="$SAVE_CPPFLAGS"
72
73# Checks for header files.
74AC_HEADER_STDC
75
76if test "$DRI" != no; then
77        AC_CHECK_FILE([${sdkdir}/dri.h],
78                      [have_dri_h="yes"], [have_dri_h="no"])
79        AC_CHECK_FILE([${sdkdir}/sarea.h],
80                      [have_sarea_h="yes"], [have_sarea_h="no"])
81        AC_CHECK_FILE([${sdkdir}/dristruct.h],
82                      [have_dristruct_h="yes"], [have_dristruct_h="no"])
83fi
84
85AC_MSG_CHECKING([whether to include DRI support])
86if test x$DRI = xauto; then
87        if test "$have_dri_h" = yes -a \
88                "$have_sarea_h" = yes -a \
89                "$have_dristruct_h" = yes; then
90                DRI="yes"
91        else
92                DRI="no"
93        fi
94fi
95AC_MSG_RESULT([$DRI])
96
97AM_CONDITIONAL(DRI, test x$DRI = xyes)
98if test "$DRI" = yes; then
99        PKG_CHECK_MODULES(DRI, [libdrm >= 2.0 xf86driproto])
100        AC_DEFINE(XF86DRI,1,[Enable DRI driver support])
101        AC_DEFINE(XF86DRI_DEVEL,1,[Enable developmental DRI driver support])
102fi
103
104if test "x$XSERVER_LIBPCIACCESS" = xyes; then
105    PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.8.0])
106    XORG_CFLAGS="$XORG_CFLAGS $PCIACCESS_CFLAGS"
107fi
108AM_CONDITIONAL(XSERVER_LIBPCIACCESS, test "x$XSERVER_LIBPCIACCESS" = xyes)
109
110AC_SUBST([DRI_CFLAGS])
111AC_SUBST([XORG_CFLAGS])
112AC_SUBST([moduledir])
113
114DRIVER_NAME=tdfx
115AC_SUBST([DRIVER_NAME])
116
117XORG_MANPAGE_SECTIONS
118XORG_RELEASE_VERSION
119
120AC_OUTPUT([
121	Makefile
122	src/Makefile
123	man/Makefile
124])
125