Home | History | Annotate | Line # | Download | only in m4 
      1 # signal_h.m4 serial 22
      2 dnl Copyright (C) 2007-2022 Free Software Foundation, Inc.
      3 dnl This file is free software; the Free Software Foundation
      4 dnl gives unlimited permission to copy and/or distribute it,
      5 dnl with or without modifications, as long as this notice is preserved.
      6 
      7 AC_DEFUN_ONCE([gl_SIGNAL_H],
      8 [
      9   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
     10   AC_REQUIRE([gl_CHECK_TYPE_SIGSET_T])
     11   gl_NEXT_HEADERS([signal.h])
     12 
     13 # AIX declares sig_atomic_t to already include volatile, and C89 compilers
     14 # then choke on 'volatile sig_atomic_t'.  C99 requires that it compile.
     15   AC_CHECK_TYPE([volatile sig_atomic_t], [],
     16     [HAVE_TYPE_VOLATILE_SIG_ATOMIC_T=0], [[
     17 #include <signal.h>
     18     ]])
     19 
     20   dnl Ensure the type pid_t gets defined.
     21   AC_REQUIRE([AC_TYPE_PID_T])
     22 
     23   AC_REQUIRE([AC_TYPE_UID_T])
     24 
     25   dnl Persuade glibc <signal.h> to define sighandler_t.
     26   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
     27   AC_CHECK_TYPE([sighandler_t], [], [HAVE_SIGHANDLER_T=0], [[
     28 #include <signal.h>
     29     ]])
     30 
     31   dnl Check for declarations of anything we want to poison if the
     32   dnl corresponding gnulib module is not in use.
     33   gl_WARN_ON_USE_PREPARE([[#include <signal.h>
     34     ]], [pthread_sigmask sigaction
     35     sigaddset sigdelset sigemptyset sigfillset sigismember
     36     sigpending sigprocmask])
     37 
     38   AC_REQUIRE([AC_C_RESTRICT])
     39 ])
     40 
     41 AC_DEFUN([gl_CHECK_TYPE_SIGSET_T],
     42 [
     43   AC_CHECK_TYPES([sigset_t],
     44     [gl_cv_type_sigset_t=yes], [gl_cv_type_sigset_t=no],
     45     [[
     46       #include <signal.h>
     47       /* Mingw defines sigset_t not in <signal.h>, but in <sys/types.h>.  */
     48       #include <sys/types.h>
     49     ]])
     50   if test $gl_cv_type_sigset_t != yes; then
     51     HAVE_SIGSET_T=0
     52   fi
     53 ])
     54 
     55 # gl_SIGNAL_MODULE_INDICATOR([modulename])
     56 # sets the shell variable that indicates the presence of the given module
     57 # to a C preprocessor expression that will evaluate to 1.
     58 # This macro invocation must not occur in macros that are AC_REQUIREd.
     59 AC_DEFUN([gl_SIGNAL_MODULE_INDICATOR],
     60 [
     61   dnl Ensure to expand the default settings once only.
     62   gl_SIGNAL_H_REQUIRE_DEFAULTS
     63   gl_MODULE_INDICATOR_SET_VARIABLE([$1])
     64   dnl Define it also as a C macro, for the benefit of the unit tests.
     65   gl_MODULE_INDICATOR_FOR_TESTS([$1])
     66 ])
     67 
     68 # Initializes the default values for AC_SUBSTed shell variables.
     69 # This macro must not be AC_REQUIREd.  It must only be invoked, and only
     70 # outside of macros or in macros that are not AC_REQUIREd.
     71 AC_DEFUN([gl_SIGNAL_H_REQUIRE_DEFAULTS],
     72 [
     73   m4_defun(GL_MODULE_INDICATOR_PREFIX[_SIGNAL_H_MODULE_INDICATOR_DEFAULTS], [
     74     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_PTHREAD_SIGMASK])
     75     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_RAISE])
     76     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_SIGNAL_H_SIGPIPE])
     77     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_SIGPROCMASK])
     78     gl_MODULE_INDICATOR_INIT_VARIABLE([GNULIB_SIGACTION])
     79   ])
     80   m4_require(GL_MODULE_INDICATOR_PREFIX[_SIGNAL_H_MODULE_INDICATOR_DEFAULTS])
     81   AC_REQUIRE([gl_SIGNAL_H_DEFAULTS])
     82 ])
     83 
     84 AC_DEFUN([gl_SIGNAL_H_DEFAULTS],
     85 [
     86   dnl Assume proper GNU behavior unless another module says otherwise.
     87   HAVE_POSIX_SIGNALBLOCKING=1; AC_SUBST([HAVE_POSIX_SIGNALBLOCKING])
     88   HAVE_PTHREAD_SIGMASK=1;      AC_SUBST([HAVE_PTHREAD_SIGMASK])
     89   HAVE_RAISE=1;                AC_SUBST([HAVE_RAISE])
     90   HAVE_SIGSET_T=1;             AC_SUBST([HAVE_SIGSET_T])
     91   HAVE_SIGINFO_T=1;            AC_SUBST([HAVE_SIGINFO_T])
     92   HAVE_SIGACTION=1;            AC_SUBST([HAVE_SIGACTION])
     93   HAVE_STRUCT_SIGACTION_SA_SIGACTION=1;
     94                                AC_SUBST([HAVE_STRUCT_SIGACTION_SA_SIGACTION])
     95   HAVE_TYPE_VOLATILE_SIG_ATOMIC_T=1;
     96                                AC_SUBST([HAVE_TYPE_VOLATILE_SIG_ATOMIC_T])
     97   HAVE_SIGHANDLER_T=1;         AC_SUBST([HAVE_SIGHANDLER_T])
     98   REPLACE_PTHREAD_SIGMASK=0;   AC_SUBST([REPLACE_PTHREAD_SIGMASK])
     99   REPLACE_RAISE=0;             AC_SUBST([REPLACE_RAISE])
    100 ])
    101