Home | History | Annotate | Line # | Download | only in gen
_setjmp.S revision 1.6.50.2 
      1 /*	$NetBSD: _setjmp.S,v 1.6.50.2 2013/01/23 00:05:21 yamt Exp $	*/
      2 
      3 /*
      4  * Copyright (c) 1997 Mark Brinicombe
      5  * All rights reserved.
      6  *
      7  * Redistribution and use in source and binary forms, with or without
      8  * modification, are permitted provided that the following conditions
      9  * are met:
     10  * 1. Redistributions of source code must retain the above copyright
     11  *    notice, this list of conditions and the following disclaimer.
     12  * 2. Redistributions in binary form must reproduce the above copyright
     13  *    notice, this list of conditions and the following disclaimer in the
     14  *    documentation and/or other materials provided with the distribution.
     15  * 3. All advertising materials mentioning features or use of this software
     16  *    must display the following acknowledgement:
     17  *	This product includes software developed by Mark Brinicombe
     18  * 4. Neither the name of the University nor the names of its contributors
     19  *    may be used to endorse or promote products derived from this software
     20  *    without specific prior written permission.
     21  *
     22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
     23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
     26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     32  * SUCH DAMAGE.
     33  */
     34 
     35 #if !defined(__SOFTFP__) && !defined(__VFP_FP__)
     36 #error FPA is not supported anymore
     37 #endif
     38 
     39 #include <machine/asm.h>
     40 #include <machine/setjmp.h>
     41 
     42 /*
     43  * C library -- _setjmp, _longjmp
     44  *
     45  *	_longjmp(a,v)
     46  * will generate a "return(v)" from the last call to
     47  *	_setjmp(a)
     48  * by restoring registers from the stack.
     49  * The previous signal state is NOT restored.
     50  *
     51  * Note: r0 is the return value
     52  *       r1-r3 are scratch registers in functions
     53  */
     54 
     55 ENTRY(_setjmp)
     56 	ldr	r1, .L_setjmp_magic
     57 	str	r1, [r0]
     58 
     59 #ifndef __SOFTFP__
     60 	add	r1, r0, #(_JB_REG_D8 * 4)
     61 	vstmia	r1, {d8-d15}
     62 	vmrs	r1, fpscr
     63 	str	r1, [r0, #(_JB_REG_FPSCR * 4)]
     64 #endif
     65 
     66 	add	r0, r0, #(_JB_REG_R4 * 4)
     67 	/* Store integer registers */
     68         stmia	r0, {r4-r14}
     69 
     70         mov	r0, #0x00000000
     71         RET
     72 
     73 .L_setjmp_magic:
     74 #ifdef __SOFTFP__
     75 	.word	_JB_MAGIC__SETJMP
     76 #else
     77 	.word	_JB_MAGIC__SETJMP_VFP
     78 #endif
     79 
     80 ENTRY(_longjmp)
     81 	ldr	r2, .L_setjmp_magic
     82 	ldr	r3, [r0]
     83 	teq	r2, r3
     84 	bne	botch
     85 
     86 #ifndef __SOFTFP__
     87 	add	r1, r0, #(_JB_REG_D8 * 4)
     88 	vldmia	r1, {d8-d15}
     89 	ldr	r1, [r0, #(_JB_REG_FPSCR * 4)]
     90 	vmsr	fpscr, r1
     91 #endif
     92 
     93 	add	r0, r0, #(_JB_REG_R4 * 4)
     94        	/* Restore integer registers */
     95         ldmia	r0, {r4-r14}
     96 
     97 	/* Validate sp and r14 */
     98 	teq	sp, #0
     99 	teqne	r14, #0
    100 	beq	botch
    101 
    102 	/* Set return value */
    103 	mov	r0, r1
    104 	teq	r0, #0x00000000
    105 	moveq	r0, #0x00000001
    106 	RET
    107 
    108 	/* validation failed, die die die. */
    109 botch:
    110 	bl	PIC_SYM(_C_LABEL(longjmperror), PLT)
    111 	bl	PIC_SYM(_C_LABEL(abort), PLT)
    112 	b	. - 8		/* Cannot get here */
    113