Home | History | Annotate | Line # | Download | only in sys 
      1 /*	$NetBSD: __clone.S,v 1.8 2020/05/05 20:43:47 skrll Exp $	*/
      2 
      3 /*-
      4  * Copyright (c) 2001 The NetBSD Foundation, Inc.
      5  * All rights reserved.
      6  *
      7  * This code is derived from software contributed to The NetBSD Foundation
      8  * by Matt Fredette.
      9  *
     10  * Redistribution and use in source and binary forms, with or without
     11  * modification, are permitted provided that the following conditions
     12  * are met:
     13  * 1. Redistributions of source code must retain the above copyright
     14  *    notice, this list of conditions and the following disclaimer.
     15  * 2. Redistributions in binary form must reproduce the above copyright
     16  *    notice, this list of conditions and the following disclaimer in the
     17  *    documentation and/or other materials provided with the distribution.
     18  *
     19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
     20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
     23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     29  * POSSIBILITY OF SUCH DAMAGE.
     30  */
     31 
     32 #include <sys/errno.h>
     33 #include "SYS.h"
     34 
     35 #ifdef WEAK_ALIAS
     36 	WEAK_ALIAS(clone, __clone)
     37 #endif
     38 
     39 /*
     40  * int clone(int (*fn)(void *), void *stack, int flags, void *arg);
     41  */
     42 ENTRY(__clone, 0)
     43 
     44 	/*
     45 	 * Sanity checks: func and stack may not be NULL.
     46 	 */
     47 	comb,=	%r0, %arg0, 8f
     48 	 nop
     49 	comb,=	%r0, %arg1, 8f
     50 	 nop
     51 
     52 	/*
     53 	 * Put the func and arg arguments into a frame in the child's stack.
     54 	 */
     55 	ldo	(HPPA_FRAME_SIZE * 2)(%arg1), %arg1
     56 	stw	%arg0, HPPA_FRAME_ARG(0)(%arg1)
     57 	stw	%arg3, HPPA_FRAME_ARG(1)(%arg1)
     58 
     59 	/*
     60 	 * The system call expects (flags, stack).
     61 	 */
     62 	copy	%arg2, %arg0
     63 	SYSCALL(__clone)
     64 	comb,<>,n %r0, %ret1, 9f
     65 	bv,n	%r0(%rp)
     66 
     67 8:
     68 	b	__cerror
     69 	 ldi	EINVAL, %t1
     70 
     71 9:	/*
     72 	 * Child: Reload the function and argument from the new stack.
     73 	 */
     74 	ldw	HPPA_FRAME_ARG(0)(%sp), %r22
     75 	ldw	HPPA_FRAME_ARG(1)(%sp), %arg0
     76 
     77 	/* Call the clone's entry point. */
     78 	stw	%r19, HPPA_FRAME_ARG(2)(%sp)
     79 	bl	$$dyncall, %r31
     80 	 copy	%r31, %rp
     81 	ldw	HPPA_FRAME_ARG(2)(%sp), %r19
     82 
     83 	/* Pass the return value to _exit(). */
     84 	copy	%ret0, %arg0
     85 	PIC_CALL(_exit)
     86 
     87 	/* NOTREACHED */
     88 EXIT(__clone)
     89