Home | History | Annotate | Line # | Download | only in gen 
      1 /*	$NetBSD: setjmp.S,v 1.19 2025/05/03 19:55:32 riastradh Exp $	*/
      2 
      3 /*-
      4  * Copyright (c) 1990 The Regents of the University of California.
      5  * All rights reserved.
      6  *
      7  * This code is derived from software contributed to Berkeley by
      8  * William Jolitz.
      9  *
     10  * Redistribution and use in source and binary forms, with or without
     11  * modification, are permitted provided that the following conditions
     12  * are met:
     13  * 1. Redistributions of source code must retain the above copyright
     14  *    notice, this list of conditions and the following disclaimer.
     15  * 2. Redistributions in binary form must reproduce the above copyright
     16  *    notice, this list of conditions and the following disclaimer in the
     17  *    documentation and/or other materials provided with the distribution.
     18  * 3. Neither the name of the University nor the names of its contributors
     19  *    may be used to endorse or promote products derived from this software
     20  *    without specific prior written permission.
     21  *
     22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
     23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
     24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
     25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
     26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
     27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
     28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
     29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
     30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
     31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
     32  * SUCH DAMAGE.
     33  *
     34  *	from: @(#)setjmp.s	5.1 (Berkeley) 4/23/90
     35  */
     36 
     37 #include <machine/asm.h>
     38 #if defined(LIBC_SCCS)
     39 	RCSID("$NetBSD: setjmp.S,v 1.19 2025/05/03 19:55:32 riastradh Exp $")
     40 #endif
     41 
     42 /*
     43  * C library -- _setjmp, _longjmp
     44  *
     45  *	longjmp(a,v)
     46  * will generate a "return(v)" from the last call to
     47  *	setjmp(a)
     48  * by restoring registers from the stack.
     49  * The previous signal state is restored.
     50  */
     51 
     52 /*
     53  * setjmp(jmp_buf env@esp[4,8))
     54  *
     55  * ELF symbol: __setjmp14, because the size of jmp_buf changed on some
     56  * platforms in 1.4.
     57  */
     58 ENTRY(__setjmp14)
     59 	/*
     60 	 * Save the callee-saves registers: %ebp, %ebx, %edi, %esi,
     61 	 * plus %esp and the return address on the stack since it
     62 	 * will be overwritten if the caller makes any subroutine
     63 	 * calls before longjmp.
     64 	 */
     65 	movl	4(%esp),%ecx		/* ecx := env */
     66 	movl	0(%esp),%edx		/* edx := return address */
     67 	movl	%edx,0(%ecx)
     68 	movl	%ebx,4(%ecx)
     69 	movl	%esp,8(%ecx)
     70 	movl	%ebp,12(%ecx)
     71 	movl	%esi,16(%ecx)
     72 	movl	%edi,20(%ecx)
     73 
     74 	/* Get the signal mask. */
     75 	leal	24(%ecx),%edx
     76 
     77 	PIC_PROLOGUE
     78 	pushl	%edx			/* oset (signal mask saved to) */
     79 	pushl	$0			/* set := NULL */
     80 	pushl	$0			/* how := 0 (ignored) */
     81 	call	PIC_PLT(_C_LABEL(__sigprocmask14))
     82 	addl	$12,%esp		/* pop sigprocmask args */
     83 	PIC_EPILOGUE
     84 
     85 	xorl	%eax,%eax		/* return 0 first time around */
     86 	ret
     87 END(__setjmp14)
     88 
     89 /*
     90  * longjmp(jmp_buf env@esp[4,8), int val@[8,12))
     91  *
     92  * ELF symbol: __longjmp14, because the size of jmp_buf changed on some
     93  * platforms in 1.4.
     94  */
     95 ENTRY(__longjmp14)
     96 	/*
     97 	 * Restore the callee-saves registers: %ebp, %ebx, %edi, %esi,
     98 	 * plus %esp and the return address on the stack.
     99 	 */
    100 	movl	4(%esp),%edx		/* edx := env */
    101 	movl	8(%esp),%eax		/* eax := val */
    102 	movl	0(%edx),%ecx		/* ecx := return address */
    103 	movl	4(%edx),%ebx
    104 	movl	8(%edx),%esp
    105 	movl	12(%edx),%ebp
    106 	movl	16(%edx),%esi
    107 	movl	20(%edx),%edi
    108 	movl	%ecx,0(%esp)		/* restore return address */
    109 
    110 	/* Restore the signal mask. */
    111 	leal	24(%edx),%edx
    112 
    113 	pushl	%eax			/* save val@eax */
    114 
    115 	PIC_PROLOGUE
    116 	pushl	$0			/* oset := NULL */
    117 	pushl	%edx			/* set (signal mask restored from) */
    118 	pushl	$3			/* how := SIG_SETMASK */
    119 	call	PIC_PLT(_C_LABEL(__sigprocmask14))
    120 	addl	$12,%esp		/* pop sigprocmask args */
    121 	PIC_EPILOGUE
    122 
    123 	popl	%eax			/* restore val@eax */
    124 
    125 	testl	%eax,%eax		/* val == 0? */
    126 	jz	3f			/* jump if val == 0 */
    127 	ret				/* return val@eax */
    128 
    129 3:	incl	%eax			/* val@eax := 1 */
    130 	ret				/* return val@eax */
    131 END(__longjmp14)
    132