Home | History | Annotate | Line # | Download | only in sys 
      1 /*	$NetBSD: __clone.S,v 1.8 2009/12/14 01:07:42 matt Exp $	*/
      2 
      3 /*-
      4  * Copyright (c) 2001 The NetBSD Foundation, Inc.
      5  * All rights reserved.
      6  *
      7  * This code is derived from software contributed to The NetBSD Foundation
      8  * by Jason R. Thorpe.
      9  *
     10  * Redistribution and use in source and binary forms, with or without
     11  * modification, are permitted provided that the following conditions
     12  * are met:
     13  * 1. Redistributions of source code must retain the above copyright
     14  *    notice, this list of conditions and the following disclaimer.
     15  * 2. Redistributions in binary form must reproduce the above copyright
     16  *    notice, this list of conditions and the following disclaimer in the
     17  *    documentation and/or other materials provided with the distribution.
     18  *
     19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
     20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
     23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     29  * POSSIBILITY OF SUCH DAMAGE.
     30  */
     31 
     32 #include <sys/errno.h>
     33 
     34 #include "SYS.h"
     35 
     36 #if defined(SYSLIBC_SCCS) && !defined(lint)
     37 	RCSID("$NetBSD: __clone.S,v 1.8 2009/12/14 01:07:42 matt Exp $");
     38 #endif /* SYSLIBC_SCCS and not lint */
     39 
     40 #ifdef WEAK_ALIAS
     41 WEAK_ALIAS(clone, __clone)
     42 #endif
     43 
     44 /*
     45  * int __clone(int (*fn)(void *), void *stack, int flags, void *arg);
     46  */
     47 LEAF(__clone)
     48 	PIC_PROLOGUE(__clone)
     49 
     50 	/*
     51 	 * Sanity checks: func and stack may not be NULL.
     52 	 */
     53 	li		v0, EINVAL
     54 	beq		a0, zero, 8f
     55 	beq		a1, zero, 8f
     56 
     57 	/*
     58 	 * We need to be able to get at the func and arg arguments
     59 	 * in the child.  Luckily, we have a convenient place to
     60 	 * do this: the child's stack.
     61 	 */
     62 	PTR_SUBU	a1, a1, CALLFRAME_SIZ
     63 	REG_S		a0, 0(a1)
     64 	REG_S		a3, SZREG(a1)
     65 
     66 	/*
     67 	 * The system call expects (flags, stack).
     68 	 */
     69 	move		a0, a2
     70 	SYSTRAP(__clone)
     71 	bne		a3, zero, 8f
     72 
     73 	bne		v1, zero, 9f	# v1 (rv[1]) == 0, parent, child pid in v0
     74 
     75 	PIC_RETURN()			# parent return
     76 
     77 8:	PIC_TAILCALL(__cerror)
     78 	/* NOTREACHED */
     79 
     80 9:	/*
     81 	 * Child: Fetch the function and argument from the new stack and create
     82 	 a frame so that the child can be safely called.
     83 	 *
     84 	 * There are already register slots on the stack from above.
     85 	 * They already include the o32 argument save area.  The
     86 	 * highest is unused.  a1 should equal sp now.
     87 	 */
     88 
     89 	REG_L		t9, 0(sp)
     90 	REG_L		a0, SZREG(sp)
     91 
     92 	REG_S		zero, CALLFRAME_RA(sp)	/* make sure stack frame ends */
     93 
     94 	/* Call the clone's entry point. */
     95 	SAVE_GP(CALLFRAME_GP)
     96 	jal		t9
     97 
     98 	/* Pass the return value to _exit. */
     99 	move		a0, v0
    100 	PIC_TAILCALL(_exit)
    101 
    102 	/* NOTREACHED */
    103 END(__clone)
    104