Home | History | Annotate | Line # | Download | only in gzboot
srtbegin.S revision 1.2 
      1 /*	$NetBSD: srtbegin.S,v 1.2 2002/02/23 18:19:09 thorpej Exp $	*/
      2 
      3 /*
      4  * Copyright (c) 2002 Wasabi Systems, Inc.
      5  * All rights reserved.
      6  *
      7  * Written by Jason R. Thorpe for Wasabi Systems, Inc.
      8  *
      9  * Redistribution and use in source and binary forms, with or without
     10  * modification, are permitted provided that the following conditions
     11  * are met:
     12  * 1. Redistributions of source code must retain the above copyright
     13  *    notice, this list of conditions and the following disclaimer.
     14  * 2. Redistributions in binary form must reproduce the above copyright
     15  *    notice, this list of conditions and the following disclaimer in the
     16  *    documentation and/or other materials provided with the distribution.
     17  * 3. All advertising materials mentioning features or use of this software
     18  *    must display the following acknowledgement:
     19  *	This product includes software developed for the NetBSD Project by
     20  *	Wasabi Systems, Inc.
     21  * 4. The name of Wasabi Systems, Inc. may not be used to endorse
     22  *    or promote products derived from this software without specific prior
     23  *    written permission.
     24  *
     25  * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
     26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     27  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     28  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
     29  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     30  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     31  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     33  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     34  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     35  * POSSIBILITY OF SUCH DAMAGE.
     36  */
     37 
     38 #include <machine/asm.h>
     39 #include <arm/armreg.h>
     40 
     41 #define	STACKSIZE	1024
     42 
     43 ENTRY(start)
     44 	/*
     45 	 * We assume we've been loaded VA==PA, or that the MMU
     46 	 * is disabled.  Make sure the MMU is disabled so that
     47 	 * we don't have to care about the caches.
     48 	 */
     49 	mrc	p15, 0, r2, c1, c0, 0
     50 	bic	r2, r2, #CPU_CONTROL_MMU_ENABLE
     51 	mcr	p15, 0, r2, c1, c0, 0
     52 
     53 	nop
     54 	nop
     55 	nop
     56 
     57 	/*
     58 	 * Check to see if &_etext == &__data_start.  If not,
     59 	 * we're most likely built for running from flash,
     60 	 * and must copy the data segment out to RAM.
     61 	 */
     62 	add	r1, pc, #(Ldata - . - 8)
     63 	ldmia	r1, {r1-r3}
     64 	cmp	r1, r2			/* &_etext == &__data_start? */
     65 	beq	2f			/* yes, in RAM */
     66 
     67 	/* Copy data segment from ROM to RAM */
     68 1:	ldrb	r0, [r1], #0x01
     69 	strb	r0, [r2], #0x01
     70 	cmp	r2, r3			/* copy done? */
     71 	bne	1b
     72 
     73 2:
     74 	/* Clear the BSS. */
     75 	add	r1, pc, #(Lbss - . - 8)
     76 	ldmia	r1, {r1, r2}
     77 	sub	r2, r2, r1
     78 	mov	r3, #0
     79 
     80 1:	strb	r3, [r1], #0x01
     81 	subs	r2, r2, #0x01
     82 	bgt	1b
     83 
     84 	/* Set the stack pointer */
     85 	add	r1, pc, #(Lstack - . - 8)
     86 	ldr	r1, [r1]
     87 	add	sp, r1, #STACKSIZE
     88 
     89 	b	_C_LABEL(main)
     90 
     91 Ldata:
     92 	.word	_C_LABEL(_etext)
     93 	.word	_C_LABEL(__data_start)
     94 
     95 Lbss:
     96 	.word	_C_LABEL(_edata)
     97 	.word	_C_LABEL(_end)
     98 
     99 Lstack:
    100 	.word	Lstackspace
    101 
    102 	.comm	Lstackspace, STACKSIZE
    103