Home | History | Annotate | Line # | Download | only in tests 
      1 include(CheckCXXCompilerFlag)
      2 include(CompilerRTCompile)
      3 include(CompilerRTLink)
      4 
      5 include_directories(..)
      6 include_directories(../..)
      7 
      8 set(MSAN_LIBCXX_CFLAGS
      9   -fsanitize=memory
     10   -fsanitize-memory-track-origins
     11   -Wno-pedantic)
     12 
     13 # Unittest sources and build flags.
     14 set(MSAN_UNITTEST_SOURCES msan_test.cc msan_test_main.cc)
     15 set(MSAN_LOADABLE_SOURCE msan_loadable.cc)
     16 set(MSAN_UNITTEST_HEADERS
     17   msan_test_config.h
     18   ../../../include/sanitizer/msan_interface.h
     19 )
     20 set(MSAN_UNITTEST_COMMON_CFLAGS
     21   -nostdinc++
     22   -isystem ${COMPILER_RT_LIBCXX_PATH}/include
     23   ${COMPILER_RT_UNITTEST_CFLAGS}
     24   ${COMPILER_RT_GTEST_CFLAGS}
     25   -I${COMPILER_RT_SOURCE_DIR}/include
     26   -I${COMPILER_RT_SOURCE_DIR}/lib
     27   -I${COMPILER_RT_SOURCE_DIR}/lib/msan
     28   -g
     29   -O2
     30   -fno-exceptions
     31   -fno-omit-frame-pointer
     32   -mno-omit-leaf-frame-pointer
     33   -Wno-deprecated-declarations
     34   -Wno-unused-variable
     35   -Wno-zero-length-array
     36   -Wno-uninitialized
     37   -Werror=sign-compare
     38   -Wno-gnu-zero-variadic-macro-arguments
     39 )
     40 # Remove -stdlib= which is unused when passing -nostdinc++.
     41 string(REGEX REPLACE "-stdlib=[a-zA-Z+]*" "" CMAKE_CXX_FLAGS ${CMAKE_CXX_FLAGS})
     42 
     43 set(MSAN_UNITTEST_INSTRUMENTED_CFLAGS
     44   ${MSAN_UNITTEST_COMMON_CFLAGS}
     45   -fsanitize=memory
     46   -fsanitize-memory-track-origins
     47   -mllvm -msan-keep-going=1
     48 )
     49 set(MSAN_UNITTEST_LINK_FLAGS
     50   -fsanitize=memory
     51   # Don't need -stdlib=libc++ because we explicitly list libc++.so in the linker
     52   # inputs.
     53   # FIXME: we build libcxx without cxxabi and need libstdc++ to provide it.
     54   -lstdc++
     55 )
     56 
     57 append_list_if(COMPILER_RT_HAS_LIBDL -ldl MSAN_UNITTEST_LINK_FLAGS)
     58 
     59 macro(msan_compile obj_list source arch kind cflags)
     60   sanitizer_test_compile(
     61     ${obj_list} ${source} ${arch}
     62     KIND ${kind}
     63     COMPILE_DEPS ${MSAN_UNITTEST_HEADERS}
     64     DEPS gtest msan
     65     CFLAGS ${MSAN_UNITTEST_INSTRUMENTED_CFLAGS} ${cflags}
     66   )
     67 endmacro()
     68 
     69 macro(msan_link_shared so_list so_name arch kind)
     70   cmake_parse_arguments(SOURCE "" "" "OBJECTS;LINK_FLAGS;DEPS" ${ARGN})
     71   set(output_so "${CMAKE_CURRENT_BINARY_DIR}/${so_name}.${arch}${kind}.so")
     72   get_target_flags_for_arch(${arch} TARGET_LINK_FLAGS)
     73   if(NOT COMPILER_RT_STANDALONE_BUILD)
     74     list(APPEND SOURCE_DEPS msan)
     75   endif()
     76   clang_link_shared(${output_so}
     77                 OBJECTS ${SOURCE_OBJECTS}
     78                 LINK_FLAGS ${TARGET_LINK_FLAGS} ${SOURCE_LINK_FLAGS}
     79                 DEPS ${SOURCE_DEPS})
     80   list(APPEND ${so_list} ${output_so})
     81 endmacro()
     82 
     83 # Main MemorySanitizer unit tests.
     84 add_custom_target(MsanUnitTests)
     85 set_target_properties(MsanUnitTests PROPERTIES FOLDER "MSan unit tests")
     86 
     87 # Adds MSan unit tests and benchmarks for architecture.
     88 macro(add_msan_tests_for_arch arch kind cflags)
     89   # Build gtest instrumented with MSan.
     90   set(MSAN_INST_GTEST)
     91   msan_compile(MSAN_INST_GTEST ${COMPILER_RT_GTEST_SOURCE} ${arch} "${kind}"
     92                                "${cflags}")
     93 
     94   # Instrumented tests.
     95   set(MSAN_INST_TEST_OBJECTS)
     96   foreach (SOURCE ${MSAN_UNITTEST_SOURCES})
     97     msan_compile(MSAN_INST_TEST_OBJECTS ${SOURCE} ${arch} "${kind}" "${cflags}")
     98   endforeach(SOURCE)
     99 
    100   # Instrumented loadable module objects.
    101   set(MSAN_INST_LOADABLE_OBJECTS)
    102   msan_compile(MSAN_INST_LOADABLE_OBJECTS ${MSAN_LOADABLE_SOURCE} ${arch} "${kind}"
    103                "-fPIC;${cflags}")
    104 
    105   # Instrumented loadable library tests.
    106   set(MSAN_LOADABLE_SO)
    107   msan_link_shared(MSAN_LOADABLE_SO "libmsan_loadable" ${arch} "${kind}"
    108                    OBJECTS ${MSAN_INST_LOADABLE_OBJECTS}
    109                    DEPS ${MSAN_INST_LOADABLE_OBJECTS})
    110 
    111   set(MSAN_TEST_OBJECTS ${MSAN_INST_TEST_OBJECTS} ${MSAN_INST_GTEST})
    112   set(MSAN_TEST_DEPS ${MSAN_TEST_OBJECTS} libcxx_msan_${arch}-build
    113                      ${MSAN_LOADABLE_SO})
    114   if(NOT COMPILER_RT_STANDALONE_BUILD)
    115     list(APPEND MSAN_TEST_DEPS msan)
    116   endif()
    117   get_target_flags_for_arch(${arch} TARGET_LINK_FLAGS)
    118   add_compiler_rt_test(MsanUnitTests "Msan-${arch}${kind}-Test" ${arch}
    119     OBJECTS ${MSAN_TEST_OBJECTS} ${MSAN_LIBCXX_SO}
    120     DEPS ${MSAN_TEST_DEPS}
    121     LINK_FLAGS ${MSAN_UNITTEST_LINK_FLAGS}
    122                ${TARGET_LINK_FLAGS}
    123                "-Wl,-rpath=${CMAKE_CURRENT_BINARY_DIR}"
    124                "-Wl,-rpath=${LIBCXX_PREFIX}/lib")
    125 endmacro()
    126 
    127 # We should only build MSan unit tests if we can build instrumented libcxx.
    128 if(COMPILER_RT_CAN_EXECUTE_TESTS AND COMPILER_RT_LIBCXX_PATH)
    129   foreach(arch ${MSAN_SUPPORTED_ARCH})
    130     get_target_flags_for_arch(${arch} TARGET_CFLAGS)
    131     set(LIBCXX_PREFIX ${CMAKE_CURRENT_BINARY_DIR}/../libcxx_msan_${arch})
    132     add_custom_libcxx(libcxx_msan_${arch} ${LIBCXX_PREFIX}
    133       DEPS ${MSAN_RUNTIME_LIBRARIES}
    134       CFLAGS ${MSAN_LIBCXX_CFLAGS} ${TARGET_CFLAGS}
    135       USE_TOOLCHAIN)
    136     set(MSAN_LIBCXX_SO ${LIBCXX_PREFIX}/lib/libc++.so)
    137 
    138     add_msan_tests_for_arch(${arch} "" "")
    139     add_msan_tests_for_arch(${arch} "-with-call"
    140                             "-mllvm;-msan-instrumentation-with-call-threshold=0")
    141   endforeach()
    142 endif()
    143