Home | History | Annotate | Line # | Download | only in gnuefi 
      1 /*	$NetBSD: elf_arm_efi.lds,v 1.1.1.1 2018/08/16 18:17:47 jmcneill Exp $	*/
      2 
      3 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
      4 OUTPUT_ARCH(arm)
      5 ENTRY(_start)
      6 SECTIONS
      7 {
      8   .text 0x0 : {
      9     _text = .;
     10     *(.text.head)
     11     *(.text)
     12     *(.text.*)
     13     *(.gnu.linkonce.t.*)
     14     *(.srodata)
     15     *(.rodata*)
     16     . = ALIGN(16);
     17   }
     18   _etext = .;
     19   _text_size = . - _text;
     20   .dynamic  : { *(.dynamic) }
     21   .data :
     22   {
     23    _data = .;
     24    *(.sdata)
     25    *(.data)
     26    *(.data1)
     27    *(.data.*)
     28    *(.got.plt)
     29    *(.got)
     30 
     31    /* the EFI loader doesn't seem to like a .bss section, so we stick
     32       it all into .data: */
     33    . = ALIGN(16);
     34    _bss = .;
     35    *(.sbss)
     36    *(.scommon)
     37    *(.dynbss)
     38    *(.bss)
     39    *(.bss.*)
     40    *(COMMON)
     41    . = ALIGN(16);
     42    _bss_end = .;
     43   }
     44 
     45   .rel.dyn : { *(.rel.dyn) }
     46   .rel.plt : { *(.rel.plt) }
     47   .rel.got : { *(.rel.got) }
     48   .rel.data : { *(.rel.data) *(.rel.data*) }
     49   _edata = .;
     50   _data_size = . - _etext;
     51 
     52   . = ALIGN(4096);
     53   .dynsym   : { *(.dynsym) }
     54   . = ALIGN(4096);
     55   .dynstr   : { *(.dynstr) }
     56   . = ALIGN(4096);
     57   .note.gnu.build-id : { *(.note.gnu.build-id) }
     58   /DISCARD/ :
     59   {
     60     *(.rel.reloc)
     61     *(.eh_frame)
     62     *(.note.GNU-stack)
     63   }
     64   .comment 0 : { *(.comment) }
     65 }
     66