Home | History | Annotate | Line # | Download | only in sparc 
      1 /*	$NetBSD: execsp.S,v 1.1 2025/04/20 22:33:41 riastradh Exp $	*/
      2 
      3 /*-
      4  * Copyright (c) 2025 The NetBSD Foundation, Inc.
      5  * All rights reserved.
      6  *
      7  * Redistribution and use in source and binary forms, with or without
      8  * modification, are permitted provided that the following conditions
      9  * are met:
     10  * 1. Redistributions of source code must retain the above copyright
     11  *    notice, this list of conditions and the following disclaimer.
     12  * 2. Redistributions in binary form must reproduce the above copyright
     13  *    notice, this list of conditions and the following disclaimer in the
     14  *    documentation and/or other materials provided with the distribution.
     15  *
     16  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
     17  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
     18  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
     19  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
     20  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
     21  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
     22  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
     23  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
     24  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
     25  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
     26  * POSSIBILITY OF SUCH DAMAGE.
     27  */
     28 
     29 #define	_LOCORE
     30 
     31 #include <machine/asm.h>
     32 
     33 RCSID("$NetBSD: execsp.S,v 1.1 2025/04/20 22:33:41 riastradh Exp $")
     34 
     35 #ifdef __PIC__
     36 #define	SETHI(label, got, reg)						      \
     37 	set	label, reg;		/* reg := &label - &GOT */	      \
     38 	ld	[got + reg], reg	/* reg := &label */
     39 #define	LO(label, reg)							      \
     40 	reg
     41 #else
     42 #define	SETHI(label, got, reg)						      \
     43 	sethi	%hi(label), reg		/* reg := &label - %lo(label) */
     44 #define	LO(label, reg)							      \
     45 	reg + %lo(label)
     46 #endif
     47 
     48 	.text
     49 
     50 /*
     51  * void execsp_start(struct ps_strings *ps_strings@g1,
     52  *     void *obj_main@g2, void (*cleanup@g3)(void))
     53  *
     54  *	ELF entry point.  Saves the stack pointer in startsp and defers
     55  *	to the usual csu __start routine.
     56  */
     57 ENTRY(execsp_start)
     58 	PIC_PROLOGUE(%o1, %o2)			/* o1 := GOT, clobber o2 */
     59 	SETHI(_C_LABEL(startsp), %o1, %o2)	/* o2 := &startup */
     60 	call	_C_LABEL(__start)		/* jump to start via PLT */
     61 	 st	%sp, [LO(_C_LABEL(startsp), %o2)] /* startsp := sp */
     62 	/* don't care what happens here, caller must never return */
     63 	ta	1				/* Tcc, trap always */
     64 END(execsp_start)
     65 
     66 /*
     67  * void execsp_ctor(void)
     68  *
     69  *	ELF constructor.  Saves the stack pointer in ctorsp and
     70  *	returns.
     71  */
     72 ENTRY(execsp_ctor)
     73 	/* Reminder: o6 is frame pointer, o7 + 8 is return address. */
     74 	PIC_PROLOGUE(%g1, %o5)			/* g1 := &GOT, clobber o5 */
     75 	SETHI(_C_LABEL(ctorsp), %g1, %o5)	/* o5 := &ctorsp */
     76 	retl					/* return to caller */
     77 	 st	%sp, [LO(_C_LABEL(ctorsp), %o5)] /* ctorsp := sp */
     78 END(execsp_ctor)
     79 
     80 	/* Make execsp_ctor a constructor. */
     81 	.pushsection .ctors,"aw",@progbits
     82 	.p2align 2
     83 	.long	_C_LABEL(execsp_ctor)
     84 	.popsection
     85 
     86 /*
     87  * int main(int argc@a0, char **argv@a1, ...)
     88  *
     89  *	Main function.  Saves the stack pointer in mainsp and returns
     90  *	zero.  We will call execsp_main in execsp_dtor once dtorsp has
     91  *	been initialized.
     92  */
     93 ENTRY(main)
     94 	/* Reminder: o6 is frame pointer, o7 + 8 is return address. */
     95 	PIC_PROLOGUE(%g1, %o5)			/* g1 := &GOT, clobber o5 */
     96 	SETHI(_C_LABEL(mainsp), %g1, %o5)	/* o5 := &mainsp */
     97 	st	%sp, [LO(_C_LABEL(mainsp), %o5)] /* mainsp := sp */
     98 	retl					/* return to caller */
     99 	 mov	0, %o0				/* return 0 */
    100 END(main)
    101 
    102 /*
    103  * void execsp_dtor(void)
    104  *
    105  *	ELF destructor.  Saves the stack pointer in dtorsp and defers
    106  *	to the C execsp_main in h_execsp.c to report the stack pointers
    107  *	back to the t_signal_and_sp parent.
    108  */
    109 ENTRY(execsp_dtor)
    110 	/* Reminder: o6 is frame pointer, o7 + 8 is return address. */
    111 	PIC_PROLOGUE(%g1, %o5)			/* g1 := &GOT, clobber o5 */
    112 	SETHI(_C_LABEL(dtorsp), %g1, %o5)	/* o5 := &dtorsp - &GOT */
    113 	st	%sp, [LO(_C_LABEL(dtorsp), %o5)] /* dtorsp := sp */
    114 	mov	%o7, %o5			/* save return address */
    115 	call	_C_LABEL(execsp_main)		/* tail call to execsp_main */
    116 	 mov	%o5, %o7			/* restore return address */
    117 END(execsp_dtor)
    118 
    119 	/* Make execsp_ctor a destructor. */
    120 	.pushsection .dtors,"aw",@progbits
    121 	.p2align 2
    122 	.long	_C_LABEL(execsp_dtor)
    123 	.popsection
    124