1# Copyright © 2017-2019 Intel Corporation
2#
3# Permission is hereby granted, free of charge, to any person obtaining a copy
4# of this software and associated documentation files (the "Software"), to deal
5# in the Software without restriction, including without limitation the rights
6# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
7# copies of the Software, and to permit persons to whom the Software is
8# furnished to do so, subject to the following conditions:
9#
10# The above copyright notice and this permission notice shall be included in
11# all copies or substantial portions of the Software.
12#
13# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
14# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
15# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
16# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
17# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
18# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
19# SOFTWARE.
20
21files_libiris = files(
22  'driinfo_iris.h',
23  'iris_batch.c',
24  'iris_batch.h',
25  'iris_binder.c',
26  'iris_binder.h',
27  'iris_blit.c',
28  'iris_border_color.c',
29  'iris_bufmgr.c',
30  'iris_bufmgr.h',
31  'iris_clear.c',
32  'iris_context.c',
33  'iris_context.h',
34  'iris_draw.c',
35  'iris_fence.c',
36  'iris_fence.h',
37  'iris_formats.c',
38  'iris_pipe.h',
39  'iris_pipe_control.c',
40  'iris_program.c',
41  'iris_program_cache.c',
42  'iris_query.c',
43  'iris_resolve.c',
44  'iris_resource.c',
45  'iris_resource.h',
46  'iris_screen.c',
47  'iris_screen.h',
48)
49
50iris_driinfo_h = custom_target(
51  'iris_driinfo.h',
52  input : files(
53    '../../../util/merge_driinfo.py',
54    '../../auxiliary/pipe-loader/driinfo_gallium.h', 'driinfo_iris.h'
55  ),
56  output : 'iris_driinfo.h',
57  command : [prog_python, '@INPUT@'],
58  capture : true,
59)
60
61iris_gen_libs = []
62foreach v : ['80', '90', '100', '110']
63  iris_gen_libs += static_library(
64    'libiris_gen@0@'.format(v),
65    ['iris_blorp.c', 'iris_state.c', gen_xml_pack],
66    include_directories : [inc_common, inc_intel, inc_nir],
67    c_args : [
68      c_vis_args, no_override_init_args, c_sse2_args,
69      '-DGEN_VERSIONx10=@0@'.format(v),
70    ],
71    dependencies : [dep_libdrm, dep_valgrind],
72  )
73endforeach
74
75libiris = static_library(
76  'iris',
77  [files_libiris, gen_xml_pack, nir_opcodes_h, nir_builder_opcodes_h,
78   iris_driinfo_h],
79  include_directories : [
80    inc_src, inc_include, inc_gallium, inc_gallium_aux, inc_intel, inc_nir,
81    inc_gallium_drivers,
82    # these should not be necessary, but main/macros.h...
83    inc_mesa, inc_mapi
84  ],
85  c_args : [c_vis_args, c_sse2_args],
86  cpp_args : [cpp_vis_args, c_sse2_args],
87  dependencies : [dep_libdrm, dep_valgrind, idep_genxml],
88  link_with : [
89    iris_gen_libs, libintel_common, libintel_compiler, libintel_dev, libisl,
90    libblorp
91  ],
92)
93
94driver_iris = declare_dependency(
95  compile_args : '-DGALLIUM_IRIS',
96  sources : iris_driinfo_h,
97  link_with : [libiris, libiriswinsys],
98)
99