1# Copyright © 2017 Dylan Baker
2# Copyright © 2018 Intel Corporation
3
4# Permission is hereby granted, free of charge, to any person obtaining a copy
5# of this software and associated documentation files (the "Software"), to deal
6# in the Software without restriction, including without limitation the rights
7# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
8# copies of the Software, and to permit persons to whom the Software is
9# furnished to do so, subject to the following conditions:
10
11# The above copyright notice and this permission notice shall be included in
12# all copies or substantial portions of the Software.
13
14# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
17# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
18# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
19# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
20# SOFTWARE.
21
22# TODO: support non-static targets
23# Static targets are always enabled in autotools (unless you modify
24# configure.ac)
25
26gallium_dri_c_args = []
27gallium_dri_ld_args = []
28gallium_dri_link_depends = []
29gallium_dri_drivers = []
30
31if with_ld_version_script
32  gallium_dri_ld_args += ['-Wl,--version-script', join_paths(meson.current_source_dir(), 'dri.sym')]
33  gallium_dri_link_depends += files('dri.sym')
34endif
35if with_ld_dynamic_list
36  gallium_dri_ld_args += ['-Wl,--dynamic-list', join_paths(meson.current_source_dir(), '../dri-vdpau.dyn')]
37  gallium_dri_link_depends += files('../dri-vdpau.dyn')
38endif
39
40libgallium_dri = shared_library(
41  'gallium_dri',
42  [files('target.c'), xmlpool_options_h],
43  include_directories : [
44    inc_common, inc_util, inc_dri_common, inc_gallium_drivers,
45    inc_gallium_winsys, include_directories('../../state_trackers/dri'),
46  ],
47  c_args : [c_vis_args],
48  cpp_args : [cpp_vis_args],
49  link_args : [ld_args_gc_sections, gallium_dri_ld_args],
50  link_depends : gallium_dri_link_depends,
51  link_with : [
52    libmesa_gallium, libdricommon, libmegadriver_stub, libdri, libgalliumvl,
53    libgallium, libglapi, libpipe_loader_static, libws_null, libwsw, libswdri,
54    libswkmsdri,
55  ],
56  dependencies : [
57    dep_selinux, dep_expat, dep_libdrm, dep_llvm, dep_thread,
58    driver_swrast, driver_r300, driver_r600, driver_radeonsi, driver_nouveau,
59    driver_kmsro, driver_v3d, driver_vc4, driver_freedreno, driver_etnaviv,
60    driver_tegra, driver_i915, driver_svga, driver_virgl,
61    driver_swr, driver_panfrost, driver_iris, driver_lima
62  ],
63  # Will be deleted during installation, see install_megadrivers.py
64  install : true,
65  install_dir : dri_drivers_path,
66  name_suffix : 'so',
67)
68
69foreach d : [[with_gallium_kmsro, [
70               'armada-drm_dri.so',
71               'exynos_dri.so',
72               'hx8357d_dri.so',
73               'ili9225_dri.so',
74               'ili9341_dri.so',
75               'imx-drm_dri.so',
76               'meson_dri.so',
77               'mi0283qt_dri.so',
78               'pl111_dri.so',
79               'repaper_dri.so',
80               'rockchip_dri.so',
81               'st7586_dri.so',
82               'st7735r_dri.so',
83	       'sun4i-drm_dri.so',
84             ]],
85             [with_gallium_radeonsi, 'radeonsi_dri.so'],
86             [with_gallium_nouveau, 'nouveau_dri.so'],
87             [with_gallium_freedreno, ['msm_dri.so', 'kgsl_dri.so']],
88             [with_gallium_softpipe or with_gallium_swr, 'swrast_dri.so'],
89             [with_gallium_softpipe and with_gallium_drisw_kms, 'kms_swrast_dri.so'],
90             [with_gallium_v3d, 'v3d_dri.so'],
91             [with_gallium_vc4, 'vc4_dri.so'],
92             [with_gallium_panfrost, 'panfrost_dri.so'],
93             [with_gallium_etnaviv, 'etnaviv_dri.so'],
94             [with_gallium_tegra, 'tegra_dri.so'],
95             [with_gallium_iris, 'iris_dri.so'],
96             [with_gallium_i915, 'i915_dri.so'],
97             [with_gallium_r300, 'r300_dri.so'],
98             [with_gallium_r600, 'r600_dri.so'],
99             [with_gallium_svga, 'vmwgfx_dri.so'],
100             [with_gallium_virgl, 'virtio_gpu_dri.so'],
101             [with_gallium_lima, 'lima_dri.so']]
102  if d[0]
103    gallium_dri_drivers += d[1]
104  endif
105endforeach
106
107meson.add_install_script(
108  prog_python.path(),
109  join_paths(meson.source_root(), 'bin/install_megadrivers.py'),
110  libgallium_dri.full_path(),
111  dri_drivers_path,
112  gallium_dri_drivers,
113)
114