configure.ac revision a1ed278c 
1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23# Initialize Autoconf
24AC_PREREQ([2.60])
25AC_INIT([xf86-input-keyboard],
26        [1.6.0],
27        [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg],
28        [xf86-input-keyboard])
29AC_CONFIG_SRCDIR([Makefile.am])
30AC_CONFIG_HEADERS([config.h])
31AC_CONFIG_AUX_DIR(.)
32
33# Initialize Automake
34AM_INIT_AUTOMAKE([foreign dist-bzip2])
35AM_MAINTAINER_MODE
36
37# Initialize libtool
38AC_DISABLE_STATIC
39AC_PROG_LIBTOOL
40
41# Initialize X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
42m4_ifndef([XORG_MACROS_VERSION],
43          [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
44XORG_MACROS_VERSION(1.8)
45XORG_DEFAULT_OPTIONS
46
47# Obtain compiler/linker options from server and required extensions
48PKG_CHECK_MODULES(XORG, [xorg-server >= 1.4] xproto inputproto)
49
50# Define a configure option for an alternate input module directory
51AC_ARG_WITH(xorg-module-dir,
52            AC_HELP_STRING([--with-xorg-module-dir=DIR],
53                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
54            [moduledir="$withval"],
55            [moduledir="$libdir/xorg/modules"])
56inputdir=${moduledir}/input
57AC_SUBST(inputdir)
58
59# The keyboard driver code is O/S specific
60case $host_os in
61  linux*)
62    IS_LINUX="yes"
63    ;;
64
65  freebsd* | kfreebsd-gnu* | netbsd* | openbsd*)
66    IS_BSD="yes"
67    ;;
68
69  solaris*)
70    IS_SOLARIS="yes"
71    ;;
72
73  gnu*)
74    IS_HURD="yes"
75    ;;
76
77  *)
78    AC_MSG_ERROR([Your operating system is not supported by the kbd driver.
79                  Contact xorg@lists.freedesktop.org if you are interested in
80                  porting it.])
81    ;;
82esac
83AM_CONDITIONAL(LINUX, [test "x$IS_LINUX" = xyes])
84AM_CONDITIONAL(BSD, [test "x$IS_BSD" = xyes])
85AM_CONDITIONAL(SOLARIS, [test "x$IS_SOLARIS" = xyes])
86AM_CONDITIONAL(HURD, [test "x$IS_HURD" = xyes])
87
88DRIVER_NAME=kbd
89AC_SUBST([DRIVER_NAME])
90
91AC_CONFIG_FILES([Makefile
92                 src/Makefile
93                 man/Makefile])
94AC_OUTPUT
95