1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23# Initialize Autoconf
24AC_PREREQ([2.60])
25AC_INIT([xf86-video-neomagic],
26        [1.3.1],
27        [https://gitlab.freedesktop.org/xorg/driver/xf86-video-neomagic/-/issues],
28        [xf86-video-neomagic])
29AC_CONFIG_SRCDIR([Makefile.am])
30AC_CONFIG_HEADERS([config.h])
31AC_CONFIG_AUX_DIR(.)
32
33# Initialize Automake
34AM_INIT_AUTOMAKE([foreign dist-xz])
35
36# Require X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
37m4_ifndef([XORG_MACROS_VERSION],
38          [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
39XORG_MACROS_VERSION(1.8)
40XORG_DEFAULT_OPTIONS
41
42# Initialize libtool
43AC_DISABLE_STATIC
44AC_PROG_LIBTOOL
45
46AH_TOP([#include "xorg-server.h"])
47
48# Define a configure option for an alternate module directory
49AC_ARG_WITH(xorg-module-dir,
50            AS_HELP_STRING([--with-xorg-module-dir=DIR],
51                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
52            [moduledir="$withval"],
53            [moduledir="$libdir/xorg/modules"])
54
55# Obtain compiler/linker options for the driver dependencies
56PKG_CHECK_MODULES(XORG, [xorg-server >= 1.0.99.901 xproto fontsproto $REQUIRED_MODULES])
57
58save_CFLAGS="$CFLAGS"
59CFLAGS="$XORG_CFLAGS"
60AC_CHECK_DECL(xf86ConfigIsaEntity,
61	      [AC_DEFINE(HAVE_ISA, 1, [Have ISA support])],
62	      [],
63	      [#include "xf86.h"])
64CFLAGS="$save_CFLAGS"
65
66# Checks for libraries.
67SAVE_CPPFLAGS="$CPPFLAGS"
68CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
69AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
70	      [XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
71	      [#include "xorg-server.h"])
72CPPFLAGS="$SAVE_CPPFLAGS"
73
74AC_ARG_ENABLE(xaa,
75              AS_HELP_STRING([--enable-xaa],
76                             [Enable legacy X Acceleration Architecture (XAA) [default=auto]]),
77              [XAA="$enableval"],
78              [XAA=auto])
79if test "x$XAA" != xno; then
80        save_CFLAGS=$CFLAGS
81        save_CPPFLAGS=$CPPFLAGS
82        CFLAGS=$XORG_CFLAGS
83        CPPFLAGS="$XORG_CFLAGS"
84        AC_CHECK_HEADERS([xaa.h], XAA=yes, XAA=no)
85        CFLAGS=$save_CFLAGS
86        CPPFLAGS=$save_CPPFLAGS
87fi
88AC_MSG_CHECKING([whether to include XAA support])
89AM_CONDITIONAL(XAA, test "x$XAA" = xyes)
90AC_MSG_RESULT([$XAA])
91
92if test "x$XSERVER_LIBPCIACCESS" = xyes; then
93    PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.8.0])
94    XORG_CFLAGS="$XORG_CFLAGS $PCIACCESS_CFLAGS"
95fi
96AM_CONDITIONAL(XSERVER_LIBPCIACCESS, test "x$XSERVER_LIBPCIACCESS" = xyes)
97
98AC_SUBST([moduledir])
99
100DRIVER_NAME=neomagic
101AC_SUBST([DRIVER_NAME])
102
103AC_CONFIG_FILES([
104                Makefile
105                src/Makefile
106                man/Makefile
107])
108AC_OUTPUT
109