configure.ac revision df9ffc95 
1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23# Initialize Autoconf
24AC_PREREQ([2.60])
25AC_INIT([xf86-video-siliconmotion],
26        [1.7.8],
27        [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg&component=Driver/siliconmotion],
28        [xf86-video-siliconmotion])
29
30# Require X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
31m4_ifndef([XORG_MACROS_VERSION],
32          [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
33XORG_MACROS_VERSION(1.8)
34XORG_DEFAULT_OPTIONS
35
36AC_CONFIG_SRCDIR([Makefile.am])
37AC_CONFIG_HEADERS([config.h])
38AC_CONFIG_AUX_DIR(.)
39
40# Initialize Automake
41AM_INIT_AUTOMAKE([foreign dist-bzip2])
42AM_MAINTAINER_MODE
43
44# Initialize libtool
45AC_DISABLE_STATIC
46AC_PROG_LIBTOOL
47
48AH_TOP([#include "xorg-server.h"])
49
50# Define a configure option for an alternate module directory
51AC_ARG_WITH(xorg-module-dir,
52            AS_HELP_STRING([--with-xorg-module-dir=DIR],
53                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
54            [moduledir="$withval"],
55            [moduledir="$libdir/xorg/modules"])
56
57# Store the list of server defined optional extensions in REQUIRED_MODULES
58XORG_DRIVER_CHECK_EXT(XV, videoproto)
59XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
60
61# Obtain compiler/linker options for the driver dependencies
62PKG_CHECK_MODULES(XORG, [xorg-server >= 1.0.99.901 xproto fontsproto $REQUIRED_MODULES])
63PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
64                  HAVE_XEXTPROTO_71="yes"; AC_DEFINE(HAVE_XEXTPROTO_71, 1, [xextproto 7.1 available]),
65                  HAVE_XEXTPROTO_71="no")
66AM_CONDITIONAL(HAVE_XEXTPROTO_71, [ test "$HAVE_XEXTPROTO_71" = "yes" ])
67
68# Checks for libraries.
69SAVE_CPPFLAGS="$CPPFLAGS"
70CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
71AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
72              [XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
73              [#include "xorg-server.h"])
74AC_CHECK_HEADER(xf86Modes.h,
75		[XMODES=yes], [XMODES=no], [#include "xorg-server.h"])
76CPPFLAGS="$SAVE_CPPFLAGS"
77
78if test "x$XSERVER_LIBPCIACCESS" = xyes; then
79    PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.8.0])
80fi
81AM_CONDITIONAL(XSERVER_LIBPCIACCESS, test "x$XSERVER_LIBPCIACCESS" = xyes)
82AM_CONDITIONAL(XMODES, test "x$XMODES" = xyes)
83
84if test "x$XMODES" = xyes; then
85    AC_DEFINE(HAVE_XMODES, 1, [X server has new mode code])
86fi
87AC_ARG_ENABLE(xaa,
88              AS_HELP_STRING([--enable-xaa],
89                             [Enable legacy X Acceleration Architecture (XAA) [default=auto]]),
90              [XAA="$enableval"],
91              [XAA=auto])
92if test "x$XAA" != xno; then
93        save_CFLAGS=$CFLAGS
94        save_CPPFLAGS=$CPPFLAGS
95        CFLAGS=$XORG_CFLAGS
96        CPPFLAGS="$XORG_CFLAGS"
97        AC_CHECK_HEADERS([xaa.h], XAA=yes, XAA=no)
98        CFLAGS=$save_CFLAGS
99        CPPFLAGS=$save_CPPFLAGS
100fi
101AC_MSG_CHECKING([whether to include XAA support])
102AM_CONDITIONAL(XAA, test "x$XAA" = xyes)
103AC_MSG_RESULT([$XAA])
104
105AC_SUBST([moduledir])
106
107DRIVER_NAME=siliconmotion
108AC_SUBST([DRIVER_NAME])
109
110AC_CONFIG_FILES([
111                Makefile
112                src/Makefile
113                man/Makefile
114])
115AC_OUTPUT
116