1#  Copyright 2005 Adam Jackson.
2#
3#  Permission is hereby granted, free of charge, to any person obtaining a
4#  copy of this software and associated documentation files (the "Software"),
5#  to deal in the Software without restriction, including without limitation
6#  on the rights to use, copy, modify, merge, publish, distribute, sub
7#  license, and/or sell copies of the Software, and to permit persons to whom
8#  the Software is furnished to do so, subject to the following conditions:
9#
10#  The above copyright notice and this permission notice (including the next
11#  paragraph) shall be included in all copies or substantial portions of the
12#  Software.
13#
14#  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
15#  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
16#  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
17#  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
18#  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
19#  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
20#
21# Process this file with autoconf to produce a configure script
22
23# Initialize Autoconf
24AC_PREREQ([2.60])
25AC_INIT([xf86-video-trident],
26        [1.4.0],
27        [https://gitlab.freedesktop.org/xorg/driver/xf86-video-trident/-/issues],
28        [xf86-video-trident])
29AC_CONFIG_SRCDIR([Makefile.am])
30AC_CONFIG_HEADERS([config.h])
31AC_CONFIG_AUX_DIR(.)
32
33# Initialize Automake
34AM_INIT_AUTOMAKE([foreign dist-xz])
35
36# Require X.Org macros 1.8 or later for MAN_SUBSTS set by XORG_MANPAGE_SECTIONS
37m4_ifndef([XORG_MACROS_VERSION],
38          [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
39XORG_MACROS_VERSION(1.8)
40XORG_DEFAULT_OPTIONS
41
42# Initialize libtool
43AC_DISABLE_STATIC
44AC_PROG_LIBTOOL
45
46AH_TOP([#include "xorg-server.h"])
47
48# Define a configure option for an alternate module directory
49AC_ARG_WITH(xorg-module-dir,
50            AS_HELP_STRING([--with-xorg-module-dir=DIR],
51                           [Default xorg module directory [[default=$libdir/xorg/modules]]]),
52            [moduledir="$withval"],
53            [moduledir="$libdir/xorg/modules"])
54
55# Store the list of server defined optional extensions in REQUIRED_MODULES
56XORG_DRIVER_CHECK_EXT(RANDR, randrproto)
57XORG_DRIVER_CHECK_EXT(RENDER, renderproto)
58XORG_DRIVER_CHECK_EXT(XV, videoproto)
59XORG_DRIVER_CHECK_EXT(DPMSExtension, xextproto)
60XORG_DRIVER_CHECK_EXT(XFreeXDGA, xf86dgaproto)
61
62# Obtain compiler/linker options for the driver dependencies
63PKG_CHECK_MODULES(XORG, [xorg-server >= 1.0.99.901 xproto fontsproto $REQUIRED_MODULES])
64PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
65                  HAVE_XEXTPROTO_71="yes"; AC_DEFINE(HAVE_XEXTPROTO_71, 1, [xextproto 7.1 available]),
66                  HAVE_XEXTPROTO_71="no")
67AM_CONDITIONAL(HAVE_XEXTPROTO_71, [ test "$HAVE_XEXTPROTO_71" = "yes" ])
68
69save_CFLAGS="$CFLAGS"
70CFLAGS="$XORG_CFLAGS"
71AC_CHECK_DECL(xf86ConfigIsaEntity,
72	      [AC_DEFINE(HAVE_ISA, 1, [Have ISA support])],
73	      [],
74	      [#include "xf86.h"])
75CFLAGS="$save_CFLAGS"
76
77SAVE_CPPFLAGS="$CPPFLAGS"
78CPPFLAGS="$CPPFLAGS $XORG_CFLAGS"
79AC_CHECK_DECL(XSERVER_LIBPCIACCESS,
80              [XSERVER_LIBPCIACCESS=yes],[XSERVER_LIBPCIACCESS=no],
81              [#include "xorg-server.h"])
82CPPFLAGS="$SAVE_CPPFLAGS"
83
84AC_ARG_ENABLE(xaa,
85              AS_HELP_STRING([--enable-xaa],
86                             [Enable legacy X Acceleration Architecture (XAA) [default=auto]]),
87              [XAA="$enableval"],
88              [XAA=auto])
89if test "x$XAA" != xno; then
90        save_CFLAGS=$CFLAGS
91        save_CPPFLAGS=$CPPFLAGS
92        CFLAGS=$XORG_CFLAGS
93        CPPFLAGS="$XORG_CFLAGS"
94        AC_CHECK_HEADERS([xaa.h], XAA=yes, XAA=no)
95        CFLAGS=$save_CFLAGS
96        CPPFLAGS=$save_CPPFLAGS
97fi
98AC_MSG_CHECKING([whether to include XAA support])
99AM_CONDITIONAL(XAA, test "x$XAA" = xyes)
100AC_MSG_RESULT([$XAA])
101
102if test "x$XSERVER_LIBPCIACCESS" = xyes; then
103    PKG_CHECK_MODULES([PCIACCESS], [pciaccess >= 0.8.0])
104    XORG_CFLAGS="$XORG_CFLAGS $PCIACCESS_CFLAGS"
105fi
106AM_CONDITIONAL(XSERVER_LIBPCIACCESS, test "x$XSERVER_LIBPCIACCESS" = xyes)
107
108# Checks for libraries.
109
110AC_SUBST([moduledir])
111
112DRIVER_NAME=trident
113AC_SUBST([DRIVER_NAME])
114
115AC_CONFIG_FILES([
116                Makefile
117                src/Makefile
118                man/Makefile
119])
120AC_OUTPUT
121